如何在Ada中打包一个通用包？

Question

我有一个Ada程序来计算从文件中取得的200个值的平均值和标准差，并且它们都能正常工作。这些包是浮动类型，如何将它们变成泛型？

平均包广告的文件是：

with Text_IO; 
package avg is 
    type int_array is Array (1..200) of integer; 
    function avrage (ParArray: int_array) return float; 
end avg; 

，平均包体：

with Text_IO; 
WITH Ada.Integer_Text_IO; USE Ada.Integer_Text_IO; 
package body avg is 
function avrage (ParArray: int_array) return float is 
    result: float :=0.0; 
    final:float :=0.0; 
    myarray: int_array:=ParArray; 
begin 
    for v in myarray'Range loop 
    result:= result + float(myarray(v)); 
    end loop; 
    final:=result/200.0; 
    return final; 
end avrage; 
end avg; 

我用“与”和“使用”调用这个包在我的主程序。请告诉我该怎么办

Answer 1

你不说你想要你的包是通用的在。

我假定要输入到某种类型Input_Value通过Input_Index索引的阵列（下面Input_Values），并且希望的输出是一些浮点类型Result_Value的。您需要功能To_Result_Value将Input_Value转换为Result_Value。

generic 
    type Input_Value is private; 
    type Input_Index is (<>); 
    type Input_Values is array (Input_Index range <>) of Input_Value; 
    type Result_Value is digits <>; 
    with function To_Result_Value (X : Input_Value) return Result_Value; 
package Statistics is 
    function Mean (Input : Input_Values) return Result_Value; 
end Statistics; 

...与执行：

package body Statistics is 
    function Mean (Input : Input_Values) return Result_Value is 
     Sum : Result_Value := 0.0; 
    begin 
     for I of Input loop 
     Sum := Sum + To_Result_Value (I); 
     end loop; 
     return Sum/Result_Value (Input’Length); 
    end Mean; 
end Statistics; 

... ...还有一点演示：

with Ada.Text_IO; 
with Statistics; 
procedure Demo is 
    type Arr is array (Integer range <>) of Integer; 
    function To_Float (X : Integer) return Float is 
    begin 
     return Float (X); 
    end To_Float; 
    package Avg is new Statistics (Input_Value => Integer, 
            Input_Index => Integer, 
            Input_Values => Arr, 
            Result_Value => Float, 
            To_Result_Value => To_Float); 
    A : Arr := (1, 2, 3, 4, 5); 
    M : Float; 
begin 
    M := Avg.Mean (A); 
    Ada.Text_IO.Put_Line ("mean is " & Float'Image (M)); 
end Demo;