保存状态的StringList

Question

在我的应用程序中的TStringList节省一些编辑值与下面的代码：

procedure TForm1.Button3Click(Sender: TObject); 
var 
    F: TStringList; 
begin 
    SaveDialog1.Filter := 'GPP files (*.GPP)|*.GPP'; 
    if SaveDialog1.Execute then 
    begin 
     F := TStringList.Create; 
     with F do 
     begin 
      Add(label7.Caption); 
      Add(label21.Caption); 
      SaveToFile(Savedialog1.Filename); 
      Free; 
     end; 
    end; 
end; 

我想也保存在这个TStringList中Tradiobutton状态。 你能帮我吗？ 问候

Answer 1

制作的回答只是为了显示正确格式化形式的代码示例

阅读：

• try/finally模式 - http://docwiki.embarcadero.com/RADStudio/XE2/en/Writing_a_Finally_Block_(Delphi)
• TIniFile类boolean值 - http://docwiki.embarcadero.com/Libraries/XE2/en/System.IniFiles.TCustomIniFile.WriteBool - 作为一个有点过时的功能有限，但是文本格式非常简单。

所以，你的代码将成为像

const ini_def_sect = 'Default Section'; 

procedure TForm1.Button3Click(Sender: TObject); 
var 
    F: TCustomIniFile; 
begin 
    SaveDialog1.Filter := 'GPP files (*.GPP)|*.GPP'; 
    if SaveDialog1.Execute then 
    begin 
     F := TIniFile.Create(SaveDialog1.Filename); 
     try 
      F.WriteString(ini_def_sect, label7.Name, label7.Caption); 
      F.WriteString(ini_def_sect, label21.Name, label21.Caption); 
      F.WriteBool(ini_def_sect, radiobutton1.Name, radiobutton1.Checked); 
      F.UpdateFile; 
     finally 
      F.Destroy; 
     end; 
    end; 
end; 

或者在VCL与基于风格（很多人不喜欢，他们不喜欢帕斯卡尔with语句）

const ini_def_sect = 'Default Section'; 

procedure TForm1.Button3Click(Sender: TObject); 
begin 
    SaveDialog1.Filter := 'GPP files (*.GPP)|*.GPP'; 
    if SaveDialog1.Execute then 
    begin 
     with TIniFile.Create(Savedialog1.Filename) do 
     try 
      WriteString(ini_def_sect, label7.Name, label7.Caption); 
      WriteString(ini_def_sect, label21.Name, label21.Caption); 
      WriteBool(ini_def_sect, radiobutton1.Name, radiobutton1.Checked); 
      UpdateFile; 
     finally 
      Destroy; 
     end; 
    end; 
end; 

而且你真的真的应该给你的变量（包括标签，表单，单选按钮等）合理的名称，而你仍然可以记住一些有关这些都意味着什么。相信我 - 一个月或两个月，你会忘记。

PS：读取结构文件就应该像这样

procedure TMainForm.btnOpenClick(Sender: TObject); 
begin 
    OpenDialog1.Filter := 'GPP files (*.GPP)|*.GPP'; 
    if OpenDialog1.Execute then 
    begin 
     with TIniFile.Create(OpenDialog1.Filename) do 
     try 
      label7.Caption := ReadString(ini_def_sect, label7.Name, ''); 
      label21.Caption := ReadString(ini_def_sect, label21.Name, ''); 
      radiobutton1.Checked := ReadBool(ini_def_sect, radiobutton1.Name, False); 
     finally 
      Destroy; 
     end; 
    end; 
end;