Sql - Column Check Constraint based on Date

Question

这不是Check constraint on date的重复，但我可能错过了另一个类似的问题。

在MS SQL，您可以创建以下限制：

ALTER TABLE [X] WITH CHECK ADD CONSTRAINT [CCCHK03_TBX] CHECK 
(
    [TBX_YEAR] = DATEPART(year, GetDate()) 
) 

您可以插入记录得很好，但我无法虽然全面测试这意味着什么，会发生什么，当服务器日期剔到2017年？我的印象是，它将允许插入2017年，但它理论上将使2016年的所有记录无效。

此表是一个仅插入表，因此记录从不意味着可更新，所以这不是问题。我主要担心的是，是否可能导致由此导致的服务器稳定性问题？

我似乎无法找到与此相关的任何内容，但MS必须有一个允许这样的约束的理由。

通常我会建议创建一个插入触发器并检查，但这让我好奇。

编辑：从目的地数据的回答扩展测试：

IF (OBJECT_ID('tempdb..#CheckTest') IS NOT NULL) 
    DROP TABLE #CheckTest 
GO 

CREATE TABLE #CheckTest (MN INT) 
ALTER TABLE #CheckTest WITH CHECK ADD CONSTRAINT CHK_MN CHECK (MN = DATEPART(SECOND, GETDATE())) 
ALTER TABLE #CheckTest CHECK CONSTRAINT CHK_MN 
GO 

-- Control Test. This will fail with: 
--Msg 547, Level 16, State 0, Line 12 
--The INSERT statement conflicted with the CHECK constraint "CHK_MN". The conflict occurred in database "tempdb", table "dbo.#CheckTest", column 'MN'. 
--The statement has been terminated. 
INSERT INTO #CheckTest (MN) 
VALUES (DATEPART(SECOND, DATEADD(SECOND, 5, GETDATE()))) 

-- Add 5 different seconds. 
DECLARE @Counter int = 0; 

WHILE @Counter < 5 
BEGIN 
    INSERT INTO #CheckTest (MN) 
    VALUES (DATEPART(SECOND, GETDATE())) 

    SET @Counter += 1; 

    -- Delay for a second. 
    WAITFOR DELAY '00:00:01'; 
END 
GO 

-- Add a different second. 
-- Disabling and Enabling a check will work just fine so long as the check already exists. 
ALTER TABLE #CheckTest NOCHECK CONSTRAINT CHK_MN; 
INSERT INTO #CheckTest (MN) 
VALUES (DATEPART(SECOND, DATEADD(SECOND, 5, GETDATE()))) 
ALTER TABLE #CheckTest CHECK CONSTRAINT CHK_MN; 

-- Control Test. This will fail with: 
--Msg 547, Level 16, State 0, Line 12 
--The INSERT statement conflicted with the CHECK constraint "CHK_MN". The conflict occurred in database "tempdb", table "dbo.#CheckTest", column 'MN'. 
--The statement has been terminated. 
INSERT INTO #CheckTest (MN) 
VALUES (DATEPART(SECOND, DATEADD(SECOND, 5, GETDATE()))) 
GO 

-- Check table contents. 
SELECT * FROM #CheckTest; 
GO 

-- Dropping and recreating the check constraint will result in an error: 
--Msg 547, Level 16, State 0, Line 37 
--The ALTER TABLE statement conflicted with the CHECK constraint "CHK_MN". The conflict occurred in database "tempdb", table "dbo.#CheckTest", column 'MN'. 
ALTER TABLE #CheckTest DROP CONSTRAINT CHK_MN; 
ALTER TABLE #CheckTest WITH CHECK ADD CONSTRAINT CHK_MN CHECK (MN = DATEPART(SECOND, GETDATE())) 
GO 

DROP TABLE #CheckTest 
GO 

编辑2：基于测试和反馈，而这肯定是一个有趣的练习，肯定摘要

出现为100％完全有效，我肯定会建议完全从“未来证明”的观点来看，因为支票永远不会被改变。就我个人而言，我认为基于触发器的约束是最容易维护的。

Answer 1

虽然我同意Vladimir Baranov的评论，我也想想以下内容。

查询优化器可以考虑CHECK限制，当数据被查询（example），但在documentation表示，这是受信任的约束

只是做查询优化器不考虑被定义 有约束NOCHECK。

当你创建约束指定WITH CHECK

ALTER TABLE [X] WITH CHECK ADD CONSTRAINT [CCCHK03_TBX] CHECK ... 

一年后（添加对应明年的某个行之后），你将不能够做到

ALTER TABLE [X] WITH CHECK CHECK CONSTRAINT [CCCHK03_TBX] 

争取做它会产生错误消息

邮件5 47，Level 16，State 0，Line ... ALTER TABLE语句 与CHECK约束“CCCHK03_TBX”冲突。冲突 发生在数据库“DbName”，表“dbo.X”，列“TBX_YEAR”中。

然而在sys.check_constraints系统视图

select is_not_trusted 
from sys.check_constraints 
where object_id = object_id('CCCHK03_TBX') 

你仍然会看到is_not_trusted = 0，那里的有效，我想，这就像is_not_trusted = 1（因为一些表中的行不再满足查询表达式） 。

我不确定，但我认为这可能会导致查询优化器将生成次优计划的情况，除非它足够聪明以至于不能在某些情况下考虑包含非确定性表达式的约束（我是无法找到这些信息，如果有人将这个信息说明的话，那就太棒了）。我相信查询优化器在这种情况下足够聪明，不会做出可能导致错误查询结果的错误判断。

Answer 2

好问题！

简短的回答是你会没事的。仅当在支票内插入或更新列时才检查支票。您现有的记录将不受年份变化的影响。

但您应该考虑一些潜在的问题。这种检查可以让你更难修改表格设计，尤其是通过SSMS（它倾向于创建一个新表格，从旧数据导入数据，删除旧数据并重命名新数据）。由于旧记录与当前约束规则不匹配，导入将失败。当然你仍然可以使用tSQL进行修改。

修宪表

-- Disable check. 
ALTER TABLE [Schema].[Table] NOCHECK CONSTRAINT [Check]; 

-- Makes changes here. 

-- Enable check. 
ALTER TABLE [Schema].[Table] CHECK CONSTRAINT [Check]; 

表内更新其他列时，你并不需要禁用检查。

测试查询

测试有点难以年，所以我换到几分钟。

CREATE TABLE #CheckTest 
    (
     MN INT CONSTRAINT CHK_MN CHECK (MN = DATEPART(MINUTE, GETDATE())) 
    ) 
; 

-- Add two different minutes. 
WHILE @COUNTER < 2 
BEGIN 

    INSERT INTO #CheckTest 
     (
      MN 
     ) 
    VALUES 
     (DATEPART(MINUTE, GETDATE())) 
    ; 

    SET @COUNTER = @COUNTER + 1; 

    -- Delay for a minute. 
    WAITFOR DELAY '00:01:00' 
END 

-- Check table contents. 
SELECT 
    * 
FROM 
    #CheckTest 
;