无需等待读取STDOUT和STDERR的外部命令

我想执行外部命令rtmpdump并单独读取它的STDOUT和STDERR，但不要等到这样的命令结束，而是读取它的部分输出，。无需等待读取STDOUT和STDERR的外部命令

什么是安全的方式做到这一点在Perl？

这是一个代码，我有“每行”的基础工作：

#!/usr/bin/perl 

use warnings; 
use strict; 
use Symbol; 
use IPC::Open3; 
use IO::Select; 

sub execute { 
    my($cmd) = @_; 
    print "[COMMAND]: $cmd\n"; 
    my $pid = open3(my $in, my $out, my $err = gensym(), $cmd); 
    print "[PID]: $pid\n"; 
    my $sel = new IO::Select; 
    $sel->add($out, $err); 
    while(my @fhs = $sel->can_read) { 
    foreach my $fh (@fhs) { 
     my $line = <$fh>; 
     unless(defined $line) { 
     $sel->remove($fh); 
     next; 
     } 
     if($fh == $out) { 
     print "[OUTPUT]: $line"; 
     } elsif($fh == $err) { 
     print "[ERROR] : $line"; 
     } else { 
     die "[ERROR]: This should never execute!"; 
     } 
    } 
    } 
    waitpid($pid, 0); 
}

但上面的代码工作只在文本模式下，我相信。要使用rtmpdump作为命令，我需要以二进制模式收集部分输出，因此不要像上面的代码一样逐行读取STDOUT。

STDOUT的二进制输出应存储在变量，不打印。

来源

2013-06-18 Ωmega

使用阻断功能（例如readline又名<>，read，等等）一个select循环内违抗使用select。

$sel->add($out, $err); 

my %bufs; 
while ($sel->count) { 
    for my $fh ($sel->can_read) { 
     my $rv = sysread($fh, $bufs{$fh}, 128*1024, length($bufs{$fh})); 

     if (!defined($rv)) { 
     # Error 
     die $! ; 
     } 

     if (!$rv) { 
     # Eof 
     $sel->remove($fh); 
     next; 
     }   

     if ($fh == $err) { 
     while ($bufs{$err} =~ s/^(.*\n)//) { 
      print "[ERROR] $1"; 
     } 
     } 
    } 
} 

print "[ERROR] $bufs{$err}\n" if length($bufs{$err}); 

waitpid($pid, 0); 

... do something with $bufs{$out} ...

但它会更易于使用IPC::Run。

use IPC::Run qw(run); 

my ($out_buf, $err_buf); 
run [ 'sh', '-c', $cmd ], 
    '>', \$out_buf, 
    '2>', sub { 
     $err_buf .= $_[0]; 
     while ($err_buf =~ s/^(.*\n)//) { 
     print "[ERROR] $1"; 
     } 
    }; 

print "[ERROR] $err_buf\n" if length($err_buf); 

... do something with $out_buf ...

来源

2013-06-20 18:01:43 ikegami

我应该澄清一个问题：除了将STDOUT数据存储到变量之外，我需要能够处理这些部分数据，无论何时可用。换句话说，某些功能应该在每次可用时调用新的STDOUT数据。 –

@Ωmega用sub ref –

替换'\ $ out_buf'就像@mpapec所说的，按照STDERR的例子。 – ikegami

如果你是一个POSIX系统上，尝试使用Expect.pm。这正是它设计要解决的问题，它还简化了向产生的进程发送击键的任务。

来源

2013-06-18 17:47:01

谢谢你的回答，但这种解决方案是不是我期待的... –

我很困惑 - 你能解释一下为什么Expect.pm不会解决问题了吗？或者你是否特别想创建一个“从头开始”的解决方案而不使用现有的库？ –

无需等待读取STDOUT和STDERR的外部命令

回答

相关问题