List :: MoreUtils mesh或'zip'函数

Question

所以这个问题纯粹是为了学习目的和好奇心，但任何人都可以解释下面的函数是如何工作的？

sub mesh (\@\@;\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@) { 
    my $max = -1; 
    $max < $#$_ && ($max = $#$_) foreach @_; 
    map { 
     my $ix = $_; 
     map $_->[$ix], @_; 
    } 0 .. $max; 
} 

它来自List::MoreUtils模块。我在我的一个应用程序中使用它，我碰巧看到了源代码，这让我觉得我根本不知道perl！任何人都可以解释这种疯狂吗？ ：） 谢谢！

Answer 1

我不会涵盖原型部分（暴徒说他会）。

这里有一个更可读的版本 - 理想情况下，它应该是不言而喻的

sub mesh (\@\@;\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@) { 

    # Calculate the maximum number of elements in each of the array refs 
    # we were passed: 

    my $maxLength = 0; 
    foreach my $array_ref (@_) { # @_ is all arrey refs passed in 
     if ($maxLength < @$array_ref) { 
      # we found an array longer than all previous ones 
      $maxLength = @$array_ref; 
     } 
    } 

    # If you represent the arrays as a matrix: 
    # ARR1 = [ a1e1, a1e2, .... a1eN], 
    # ARR2 = [ a2e1, a2e2, .... a2eN], 
    # ... 
    # ARR2 = [ aMe1, aMe2, .... aMeN]; 
    # Then, we are simply walking through the matrix; 
    # each column top to bottom then move on to next column left to right 
    # (a1e1, a2e1, ... aMe1, a1e2, a2e2, ... aMeN) 

    my @results; 
    for (my $index = 0; $index < $maxLength; $index++) { # Iterate over columns 
     foreach my $array_ref (@_) { # Iterate over per-row cells in each column 
      push @results, $array_ref->[$index]; 
     } 
    } ; 
} 

这里有一个评论原始版本

sub mesh (\@\@;\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@) { 

    # Calculate the largest index in each of the array refs 
    # @_ is an array of all the input arrayrefs 
    # $_ will be one of the array refs in a foreach loop 
    # $#{$X} is the largest index in arrayref X; thus 
    # $#$_ is the largest index in arrayref $_ 
    my $max = -1; 
    $max < $#$_ && ($max = $#$_) foreach @_; 

    # Return a list, obtained by looping 
    # over every index from 0 to the maximal index of any of the arrays 
    # Then, for each value of the index ($ix), push into the resulting list 
    # an element with that index from each of the arrays. 
    map { 
     my $ix = $_; 
     map $_->[$ix], @_; 
    } 0 .. $max; 
} 

---

---

一个不寻常的事情在这个方法是function signature (prototype)。

sub mesh (\@\@;\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@\@) { 

由于@mob和@ikegami在评论中指出的明智，

... It instructs Perl to expect between 2 and 32 named arrays, and to pass them to the function (in @_) as array references. So if you call mesh @a,@b,@c , then @_ in mesh is set to (\@a,\@b,\@c) rather than one "flat" list with all the individual elements of @a, @b, and @c (mob)
... They technically don't need to be named, just dereferenced. e.g. @$ref and @{[qw(foo bar)]} work just as well as @a . In other words, it has to start with @ (and not be a slice). (ikegami)

换句话说，下面的2个呼叫的行为相同

my @a1 = (1); 
my @a2 = (2); 
sub mesh_prototype(\@\@) { print "$_->[0]\n" } 
sub mesh_pass_arrayref() { print "$_->[0]\n" } 
mesh_prototype(@a1, @a2); 
mesh_pass_arrayref(\@a1, \@a2); 

这样做是为了你可以将单个数组（而不是arrayrefs）作为参数传递给表现得像内置插件的函数（例如，map/sort）

要回答扎伊德的查询，这就是如果1点或33的阵列被列为参数来调用到mesh()发生了什么，它会产生一个编译时错误：

Not enough arguments for main::mesh at mesh.pl line 16, near "@a1)" 
Execution of mesh.pl aborted due to compilation errors. 

Too many arguments for main::mesh at mesh.pl line 16, near "@a2)" 
Execution of mesh.pl aborted due to compilation errors.