通过数据透视表循环并删除相同的值

Question

我想通过循环表中的所有数据透视表并删除它们中具有相同名称的所有值字段：“Total Net Spend”和“％Split”（请参见图片参考）。

我想下面的代码，但它只能通过他们都在第一枢轴工作，不会循环。如何编辑代码，以便它将删除工作表中所有透视表上的“总净支出”和“％分割”列？

Sub Loop_Pivots() 

Dim PT As PivotTable, PTField As PivotField 

Set PT = Sheets("Sheet1").PivotTables("Pivot1") 
With PT 
    .ManualUpdate = True 
    For Each PTField In .DataFields 
     PTField.Orientation = xlHidden 
    Next PTField 
    .ManualUpdate = False 
End With 
Set PT = Nothing 

End Sub 

Answer 1

要遍历PivotTables尝试另一个foreach环这样

Sub Loop_Pivots() 

    Dim PT As PivotTable, PTField As PivotField 
    For Each PT In Sheets("Sheet1").PivotTables 
     With PT 
      .ManualUpdate = True 
      For Each PTField In .DataFields 
       PTField.Orientation = xlHidden 
      Next PTField 
      .ManualUpdate = False 
     End With 
    Next PT 
    Set PT = Nothing 
End Sub 

Answer 2

尝试下面的代码：

Option Explicit 

Sub Loop_Pivots() 

Dim PT   As PivotTable 
Dim PTField  As PivotField 

For Each PT In Sheets("Sheet1").PivotTables 

    With PT 
     .ManualUpdate = True 
     For Each PTField In .PivotFields '<-- loop through all pivot fields 
      Select Case PTField.Name 
       Case "Total Net Spend", "% Split" '<-- if Field Name equals on of the 2 in this case 
        PTField.Orientation = xlHidden 
      End Select 
     Next PTField 
     .ManualUpdate = False 
    End With 
    Set PT = Nothing 
Next PT 

End Sub