是否有可能为特定的Perl类获取所有有效的方法？

Question

是否有可能获得特定Perl类的所有有效方法？

我想操纵一个类的符号表并获得它的所有方法。我发现我可以通过$obj->can($method)从非子程序中分离出子程序，但这并不完全符合我的想法。

以下回报：

subroutine, Property, croak, Group, confess, carp, File 

然而，subroutine不是方法，（只是一个子程序），并croak，confess，并都导入到我的包。

我真正想要打印的是：

Property,Group, File 

但我会采取：

subroutine, Property,Group, File 

下面是我的程序：

#! /usr/bin/env perl 

use strict; 
use warnings; 
use feature qw(say); 

my $sections = Section_group->new; 
say join ", ", $sections->Sections; 

package Section_group; 
use Carp; 

sub new  { 
    return bless {}, shift; 
} 

sub Add { 
    my $self    = shift; 
    my $section    = shift; 
} 

sub Sections { 
    my $self    = shift; 

    my @sections; 
    for my $symbol (keys %Section_group::) { 
     next if $symbol eq "new"; # This is a constructor 
     next if $symbol eq "Add"; # Not interested in this method 
     next if $symbol eq "Sections";  # This is it's own method 
     push @sections, $symbol if $self->can($symbol); 
    } 

    return wantarray ? @sections : \@sections; 
} 

sub subroutine { 
    my $param1    = shift; 
    my $param2    = shift; 
} 

sub Group { 
    my $self    = shift; 
    my $section    = shift; 
} 

sub File { 
    my $self    = shift; 
    my $section    = shift; 
} 

sub Property { 
    my $self    = shift; 
    my $section    = shift; 
} 

Answer 1

这是相当琐碎。我们只想保留最初在我们的软件包中定义的那些子名称。每个CV（代码值）都有一个指向定义它的包的指针。由于B，我们可以检查：

use B(); 

... 

if (my $coderef = $self->can($symbol)) { 
    my $cv = B::svref_2object $coderef; 
    push @sections, $symbol if $cv->STASH->NAME eq __PACKAGE__; 
} 

# Output as wanted 

也就是说，我们使用svref_2object进行反省。这将返回一个表示内部perl数据结构的Perl对象。

如果我们查看一个coderef，我们得到一个B::CV object，它代表内部CV。 CV中的STASH字段指向其定义的Stash。如您所知，Stash只是一个特殊的散列（内部表示为HV），因此$cv->STASH返回B::HV。 HV的NAME字段包含HV为Stash且不是常规散列的Stash的完全限定软件包名称。

现在我们有我们需要的所有信息，并且可以比较想要的包名称和coderef的存储名称。

当然，这是简化的，你会想通过@ISA一般类的递归。

---

没有人喜欢污染的命名空间。值得庆幸的是，有一些模块可以从存储器中移除外来符号，例如namespace::clean。在编译时知道所有正在调用的子程序的CV时，这是没有问题的。

Answer 2

你想做什么？为什么一个类如何定义或实现它所响应的方法？

Perl是一种动态语言，所以这意味着方法根本不必存在。与AUTOLOAD，一种方法可能是完美的，可调用的，但从不出现在符号表中。一个好的界面会使can在这些情况下工作，但可能会出现类或对象决定用false来响应的情况。

Package::Stash模块可以帮助您在特定命名空间中查找已定义的子例程，但正如您所说，它们可能未在同一个文件中定义。类中的方法可能来自继承的类。如果你关心他们来自哪里，你可能做错了。