批处理语句不起作用

Question

在我的批处理文件中，我有一个if语句，这是行为不端。我错过了哪些是造成这种情况的原因？

if "%moveType%"=="file" (
echo Arcval File Move 1>>"%logfile%" 2>&1 

if not exist %arcval_folder% (
    mkdir %arcval_folder% 
    echo Directory: %arcval_folder% created. 1>>"%logfile%" 2>&1 
    ECHO. 1>>"%logfile%" 2>&1 
) 

echo xcopy "%src_dir%" "%tgt_dir%" 1>>"%logfile%" 2>&1 
echo F|xcopy "%src_dir%" "%tgt_dir%" 1>>"%logfile%" 2>&1 

if ERRORLEVEL 1 (
    echo Failure: File not found, Arcval File not promoted. 1>>"%logfile%" 2>&1 
    echo "\\ntmaster\code\reskit\blat.exe" "\\ntmaster\batch\Jobs\Test\far\Common\ArcvalFailure-emailTxt.txt" -t "%promoter_email%" -c "%initiator_email%" -s "Failure! File not found, Arcval File not promoted." -f "%initiator_email%" 1>>"%logfile%" 2>&1 
    "\\ntmaster\code\reskit\blat.exe" "\\ntmaster\batch\Jobs\Test\far\Common\ArcvalFailure-emailTxt.txt" -t "%promoter_email%" -c "%initiator_email%" -s "Failure! File not found, Arcval File not promoted." -f "%initiator_email%" 1>>"%logfile%" 2>&1 
    ECHO. 1>>"%logfile%" 2>&1 

    echo Failure email sent, exiting program. 

) else (
    echo Success: Arcval File was successfully promoted. 1>>"%logfile%" 2>&1 
    echo "\\ntmaster\code\reskit\blat.exe" "\\ntmaster\batch\Jobs\Test\far\Common\ArcvalSuccess-emailTxt.txt" -t "%promoter_email%" -c "%initiator_email%" -s "Success! Arcval File was successfully promoted." -f "%initiator_email%" 1>>"%logfile%" 2>&1 
    "\\ntmaster\code\reskit\blat.exe" "\\ntmaster\batch\Jobs\Test\far\Common\ArcvalSuccess-emailTxt.txt" -t "%promoter_email%" -c "%initiator_email%" -s "Success! Arcval File was successfully promoted." -f "%initiator_email%" 1>>"%logfile%" 2>&1 
    ECHO. 1>>"%logfile%" 2>&1 

    echo Success email sent, exiting program. 
) 

goto end 

) 

if "%moveType%"=="directory" (
echo Polysystems Directory Move 1>>"%logfile%" 2>&1 

if not exist %tgt_dir% (
    mkdir %tgt_dir% 
    echo Directory: %tgt_dir% created. 1>>"%logfile%" 2>&1 
    ECHO. 1>>"%logfile%" 2>&1 
) else (
    echo ERROR: Polysystems Target directory already exists, Source was not promoted. 1>>"%logfile%" 2>&1 
    echo "\\ntmaster\code\reskit\blat.exe" "\\ntmaster\batch\Jobs\Test\far\Common\polySystemsErr-emailTxt.txt" -t "%promoter_email%" -c "%initiator_email%" -s "ERROR! Polysystems Target directory already exists, Source was not promoted." -f "%initiator_email%" 1>>"%logfile%" 2>&1 
    ECHO. 1>>"%logfile%" 2>&1 

    "\\ntmaster\code\reskit\blat.exe" "\\ntmaster\batch\Jobs\Test\far\Common\polySystemsErr-emailTxt.txt" -t "%promoter_email%" -c "%initiator_email%" -s "ERROR! Polysystems Target directory already exists, Source was not promoted." -f "%initiator_email%" 1>>"%logfile%" 2>&1 
    ECHO. 1>>"%logfile%" 2>&1 
    echo Failure email sent, exiting program. 1>>"%logfile%" 2>&1 
    exit 
) 

echo xcopy %src_dir% %tgt_dir% /Y /Z /C /F /E 1>>"%logfile%" 2>&1 
echo F|xcopy %src_dir% %tgt_dir% /Y /Z /C /F /E 1>>"%logfile%" 2>&1 

echo Success: Polysystems Directory was successfully promoted. 1>>"%logfile%" 2>&1 
echo "\\ntmaster\code\reskit\blat.exe" "\\ntmaster\batch\Jobs\Test\far\Common\polySystemsSuccess-emailTxt.txt" -t "%promoter_email%" -c "%initiator_email%" -s "Success! Polysystems Directory was successfully promoted." -f "%initiator_email%" 1>>"%logfile%" 2>&1 
ECHO. 1>>"%logfile%" 2>&1 

"\\ntmaster\code\reskit\blat.exe" "\\ntmaster\batch\Jobs\Test\far\Common\polySystemsSuccess-emailTxt.txt" -t "%promoter_email%" -c "%initiator_email%" -s "Success! Polysystems Directory was successfully promoted." -f "%initiator_email%" 1>>"%logfile%" 2>&1 
ECHO. 1>>"%logfile%" 2>&1 
echo Success email sent, exiting program. 1>>"%logfile%" 2>&1 

goto end 
) 

这是它是如何表现：当移动类型==文件，它贯穿，如果声明就好了，但是，当移动式==目录，脚本死了，没有做任何事情。

当if语句切换（目录第一，第二的文件）目录中的作品和文件不

Answer 1

我只能想出一个可能会导致您描述的行为的场景。我怀疑，如果moveType =目录，则不能定义arcval_folder。相反，如果moveType = file，则不能定义tgt_dir。

你的代码在这种情况下会失败的原因是因为复杂的IF语句被一次全部解析，包括所有相关的代码块。即使IF语句的计算结果为FALSE，整个复杂语句也必须具有有效的语法。如果IF语句的某些部分没有正确解析，那么批处理脚本将以语法错误结束。

所以，如果moveType =目录和arcval_folder是不确定的，那么第一个IF块如下所示后变量扩展：

if "file" == "file" (
    echo .... 
    if not exist (
    etc. 
) 
    etc. 
    goto end 
) 

内IF NOT EXIST声明无效，而整个脚本失败。

如果moveType = file且tgt_dir未定义，那么第二个IF块将是无效的，但第一个IF块中的GOTO END绕过问题。如果您颠倒IF块的顺序，则在这种情况下只有问题。

最简单的解决方案是将IF NOT EXIST文件夹放在引号中。 Foxidrive也是正确的，你可能应该包括一个尾随\，以确保你只是在寻找文件夹。

if not exist "%arcval_folder%\" (... 

if not exist "%tgt_dir%\" (... 

Answer 2

使用双引号字符，丢弃所有多余的空白：

if "%moveType%"=="directory" (

Answer 3

从这里%tgt_dir%和其他变量不用双引号，空格/ &字符会打破它。

if not exist %tgt_dir% (

，并在本次测试还需要一个尾部的反斜杠否则就太匹配文件名。

if not exist "%tgt_dir%\" (