如何在使用VBA的Excel单元格中获得月份和日期？

Question

所以这里是我的场景：

我有一个思科登录和注销报告，将我的数据导出到Excel中。大！唯一的问题是，它在一天内给我多次登录时间，所以我试图只进行第一次登录尝试，并在那一天把剩下的东西扔掉，然后转移到下一次。

该单元由Cisco预先格式化为m/d/yyyy" "h\:mm\:ss AM/PM。我在教自己的VBA，我想从单个单元中获得m/d/yyyy，并将其与其他单元进行比较。如果日期存在，我想删除这些行。

实施例：

5/2/2012 2:55:12PM 
5/2/2012 3:00:00PM 
5/2/2012 3:01:00PM 
5/3/2012 2:56:01PM 

我要删除的第二和第三条目在for循环中。

让我知道，如果这不明确，并非常感谢哟你的帮助！

Answer 1

您提到过preformatted by Cisco as m/d/yyyy" "h\:mm\:ss AM/PM.但上面的示例与该格式不匹配。你给的样品应该是

5/2/2012 2:55:12 PM 
5/2/2012 3:00:00 PM 
5/2/2012 3:01:00 PM 
5/3/2012 2:56:01 PM 

即具有空间PM

下面这段代码示例是基于格式m/d/yyyy h\:mm\:ss AM/PM

CODE

Sub Sample() 
    Dim ws As Worksheet 
    Dim lRow As Long, i As Long 
    Dim delRange As Range 

    '~~> Set this to the sheet where you have the data 
    Set ws = Sheets("Sheet1") 

    With ws 
     '~~> Sort the data in ascending order 
     .Range("A:A").Sort key1:=.Range("A1"), order1:=xlAscending 

     '~~> Get the last row 
     lRow = .Range("A" & .Rows.Count).End(xlUp).Row 

     '~~> loop through the cells 
     For i = 2 To lRow 
      '~~> Check if date matches 
      If Application.Evaluate("=DATE(YEAR(A" & i & "),MONTH(A" & i & "),DAY(A" & i & "))") = _ 
      Application.Evaluate("=DATE(YEAR(A" & i - 1 & "),MONTH(A" & i - 1 & "),DAY(A" & i - 1 & "))") Then 
       '~~> Check if the value is greater 
       If .Range("A" & i).Value > .Range("A" & i - 1).Value Then 
        '~~> identify cells to delete 
        If delRange Is Nothing Then 
         Set delRange = .Range("A" & i) 
        Else 
         Set delRange = Union(delRange, .Range("A" & i)) 
        End If 
       End If 
      End If 
     Next i 

     '~~> Delete cells 
     If Not delRange Is Nothing Then delRange.Delete 
    End With 
End Sub 

前SCREENSHOT