如何匹配perl中缺少数组元素？

Question

我想通过使用数组元素来匹配数据上的缺席单词。 我的代码是

use warnings; 
use strict; 
my @ar = qw(one two three four five six seven eight nine ten); 
my @data = <DATA>; 
print "Absence word in the data\n"; 
foreach my $mat(@ar){ 
    my $nonmatch; 
    foreach my $dat (@data){ 
     $nonmatch = grep{m/(?!$mat)/} $dat; 
    } 
    print "$nonmatch\n"; 
} 
__DATA__ 
eight two four one two three four seven eight ten one two seven 

首先参阅数据阵列元件上的阵列元素的值是在仅打印在数据不存在。

我预期成果是：

Absence word in the data 
five 
six 
nine 

我该怎么办呢

Answer 1

使用见过风格散列作为蓝本在perlfaq4 - How can I tell whether a certain element is contained in a list or array?

use warnings; 
use strict; 

my %seen = map { $_ => 1 } map { split ' ' } <DATA>; 

my @ar = qw(one two three four five six seven eight nine ten); 

print "Absence word in the data\n"; 
print "$_\n" for grep { !$seen{$_} } @ar; 

__DATA__ 
eight two four one two three four seven eight ten one two seven 

输出：

Absence word in the data 
five 
six 
nine 

Answer 2

您可以使用哈希片@seen{@r}存储在%seen哈希从@r所有见过的词，检查后对@ar这些哈希键阵列，

use warnings; 
use strict; 

my @ar = qw(one two three four five six seven eight nine ten); 
my %seen; 
while (my $mat = <DATA>) { 
    my @r = split (' ', $mat); 
    @seen{@r} =(); 
} 
print "Absence word in the data\n"; 
print "$_\n" for grep { not exists $seen{$_} } @ar; 

__DATA__ 
eight two four one two three four seven eight ten one two seven 

输出

Absence word in the data 
five 
six 
nine 

Answer 3

这听起来像一个问题，我曾在一个点上，我想出了代码，是我创建的基础上，在此页面中的信息下面的代码：

https://www.safaribooksonline.com/library/view/perl-cookbook/1565922433/ch04s08.html

# assume @A and @B are already loaded 
%seen =();      # lookup table to test membership of B 
@aonly =();      # answer 

# build lookup table 
foreach $item (@B) { $seen{$item} = 1 } 

# find only elements in @A and not in @B 
foreach $item (@A) { 
    unless ($seen{$item}) { 
     # it's not in %seen, so add to @aonly 
     push(@aonly, $item); 
    } 
} 

Answer 4

创建一个散列，其中包含__DATA__中的所有单词作为关键字（可以使用散列片在一行中完成），然后过滤未散列的单词（也可以使用grep在一行中完成）。

use warnings; 
use strict; 
my @ar = qw(one two three four five six seven eight nine ten); 

my $data = join '', (<DATA>); 
my @data_words = split ' ', $data; # get a list of words 

my %data; 
@data{@data_words} = @data_words; # fill a hash with the words from __DATA__ 

my @missing = grep { !exists $data{$_}; } @ar; # filter words 

print "Absence word in the data: @missing\n"; 

__DATA__ 
eight two four one two three four seven eight ten one two seven 

Answer 5

该解决方案从您正在查找的物品列表开始，然后丢弃沿途所看到的任何物品，然后打印出剩下的物品。

如果在%unseen哈希中仍然有任何密钥，您可以通过检查while循环的底部来优化大数据。我在测试数据中添加了另一行，并添加了“16”这个词，以确保它能够处理多行，并且我们没有在那里得到“六”的误报。

use warnings; 
use strict; 

my @to_match = qw/ one two three four five six seven eight nine ten /; 
my %unseen; 
$unseen{$_} = 1 for @to_match; 
while (my $line = <DATA>) { 
    foreach my $match_this (@to_match) { 
     delete $unseen{$match_this} if $line =~/\b$match_this\b/; 
    } 
} 
print "Words absent from the data:\n". join "\n", keys %unseen; 
print "\n"; 
__DATA__ 
eight two four one two three four seven eight ten one two seven 
sixteen 

Answer 6

两件事情：

始终chomp你读什么这包括__DATA__：

my @data = <DATA>; # The NL is in each element 
chomp @data;   # Now it isn't! 

如果你不chomp，你会检查看看one匹配one\n。此外，由于您将整个__DATA__放在一行上，因此它将作为单行输入读取。您将不得不使用split将其分隔到数组中。

第二件事：通常，当你问这是在吗？t类型的问题，你应该立即想到哈希。散列可以很快用于查找项目。在这种情况下，你会做你的数据的哈希值，然后验证是否在你的列表中的每个项目在散列：

#! /usr/bin/env perl 
# 

use strict; 
use warnings; 
use feature qw(say); 

my @list = qw(one two three four five six seven eight nine ten); 
my @data = <DATA>; 
chomp @data;  # Don't forget! 

# 
# Translate your input as a hash 
# 

my %data_hash; 
for my $element (@data) { 
    $data_hash{$element} = 1; 
} 

for my $element (@list) { 
    if (not exists $data_hash{$element}) { 
     say "$element isn't in the list"; 
    } 
} 
__DATA__ 
eight 
two 
four 
one 
two 
three 
four 
seven 
eight 
ten 
one 
two 
seven 

注意，map命令给你写这个循环的一个短的方法：

# 
# Translate your input as a hash 
# 

my %data_hash; 
for my $element (@data) { 
    $data_hash{$element} = 1; 
} 

现在可以缩短为单行：

# 
# Translate your input as a hash 
# 

my %data_hash = map { $_ => 1 } @data; 

这是翻动数组的哈希值的常见方式，因此大多数开发人员会简单地使用它。