单元测试GORM调用与闭合

Question

我有一个Grails的服务，做了where这样的查询：

List<Car> search(Long makeId = null) { 
    Car.where { 
     join("make") 
     if(makeId) { 
      make.id == makeId 
     } 
    }.findAll() 
} 

我试图单元测试与斯波克这样的：

def setup() { 
    GroovyMock(Car, global: true) 
} 

void "test search"() { 
    when: 
     service.search() 
    then: 
     1 * Car.where {} 
} 

但是，我似乎无法找到一种方法来测试闭包的内容。

我可以得到测试通过验证1 * Car.where(_)通过，但我怎么能在封闭的内容的断言，即认为join被称为并在需要时make.id约束只规定？

Answer 1

您可以将闭包的委托设置为DetachedCriteria的模拟来对其进行断言。 DetachedCriteria是gorm构建查询的主要类。

实施例：

given: 'Mocking DetachedCriteria' 
DetachedCriteria detachedCriteriaMock = Mock(DetachedCriteria) 
and: 'Just to avoid nullPointerException when findAll() call happens on service' 
1 * detachedCriteriaMock.iterator() >> [].listIterator() 
when: 
service.search(1L) 
then: 
// Capture the argument 
1 * Car.where(_) >> { args -> 
    args[0].delegate = detachedCriteriaMock 
    args[0].call() 

    return detachedCriteriaMock 
} 

// Join is a method on detached criteria 
1 * detachedCriteriaMock.join('make') 
// Make is an association, so detachedCriteria uses the methodMissing to find the property. 
// In this case, we call the closure setting the delegate to the mock 
1 * detachedCriteriaMock.methodMissing('make', _) >> { args -> 
    // args[1] is the list of arguments. 
    // args[1][0] is the closure itself passed to detachedCriteria 
    args[1][0].delegate = detachedCriteriaMock 
    args[1][0].call() 
} 
// If id is passed, it must compare (eq method) with value 1 
1 * detachedCriteriaMock.eq('id', 1L)