有没有人知道如何在不使用NERDTree的情况下关闭VIM中的缓冲区? NERD Tree通常会将您的显示器分成两个垂直窗口(左侧的浏览器,右侧的主窗口)。如果你关闭一个缓冲区,那么你将被缩小到一个巨大的文件浏览窗口。如果您选择另一个文件,则会打开第二个窗口,但是会将其分开。有任何想法吗?VIM和NERD树 - 正确关闭缓冲区
回答
我不使用NERD树,但如果我理解正确,您希望在不关闭窗口的情况下关闭缓冲区。如果我的推理是正确的,请尝试使用此脚本。
" Delete buffer while keeping window layout (don't close buffer's windows).
" Version 2008-11-18 from http://vim.wikia.com/wiki/VimTip165
if v:version < 700 || exists('loaded_bclose') || &cp
finish
endif
let loaded_bclose = 1
if !exists('bclose_multiple')
let bclose_multiple = 1
endif
" Display an error message.
function! s:Warn(msg)
echohl ErrorMsg
echomsg a:msg
echohl NONE
endfunction
" Command ':Bclose' executes ':bd' to delete buffer in current window.
" The window will show the alternate buffer (Ctrl-^) if it exists,
" or the previous buffer (:bp), or a blank buffer if no previous.
" Command ':Bclose!' is the same, but executes ':bd!' (discard changes).
" An optional argument can specify which buffer to close (name or number).
function! s:Bclose(bang, buffer)
if empty(a:buffer)
let btarget = bufnr('%')
elseif a:buffer =~ '^\d\+$'
let btarget = bufnr(str2nr(a:buffer))
else
let btarget = bufnr(a:buffer)
endif
if btarget < 0
call s:Warn('No matching buffer for '.a:buffer)
return
endif
if empty(a:bang) && getbufvar(btarget, '&modified')
call s:Warn('No write since last change for buffer '.btarget.' (use :Bclose!)')
return
endif
" Numbers of windows that view target buffer which we will delete.
let wnums = filter(range(1, winnr('$')), 'winbufnr(v:val) == btarget')
if !g:bclose_multiple && len(wnums) > 1
call s:Warn('Buffer is in multiple windows (use ":let bclose_multiple=1")')
return
endif
let wcurrent = winnr()
for w in wnums
execute w.'wincmd w'
let prevbuf = bufnr('#')
if prevbuf > 0 && buflisted(prevbuf) && prevbuf != w
buffer #
else
bprevious
endif
if btarget == bufnr('%')
" Numbers of listed buffers which are not the target to be deleted.
let blisted = filter(range(1, bufnr('$')), 'buflisted(v:val) && v:val != btarget')
" Listed, not target, and not displayed.
let bhidden = filter(copy(blisted), 'bufwinnr(v:val) < 0')
" Take the first buffer, if any (could be more intelligent).
let bjump = (bhidden + blisted + [-1])[0]
if bjump > 0
execute 'buffer '.bjump
else
execute 'enew'.a:bang
endif
endif
endfor
execute 'bdelete'.a:bang.' '.btarget
execute wcurrent.'wincmd w'
endfunction
command! -bang -complete=buffer -nargs=? Bclose call <SID>Bclose('<bang>', '<args>')
nnoremap <silent> <Leader>bd :Bclose<CR>
nnoremap <silent> <Leader>bD :Bclose!<CR>
:bd
适用于Vim 7.3和NERDTree 4.1.0。
是的,刚刚更新了MacVim 7.3,现在它也适用于我。 – mxgrn 2010-11-11 19:08:40
嗯,我在Ubuntu 12.04上的Vim 7.3和NERDTree 4.1上,我仍然有OP的问题。 – Milimetric 2012-09-19 02:49:18
在Windows 7机器上,在Vim 7.4,NERDTree 4.2.0上不起作用。 – Juan 2015-05-07 17:27:16
bufkill插件似乎也解决了这个问题。
试试这个映射:nnoremap <leader>q :bp<cr>:bd #<cr>
的伟大工程,这么简单的:) – newUserNameHere 2014-11-30 17:56:35
绝对华丽的解决方案。这是在我的舌头上。 – cbartondock 2017-04-26 20:08:24
- 1. Vim-airline关闭缓冲区/退出vim
- 2. Vim关闭窗口而不关闭缓冲区
- 3. 防止NERD树开始启动缓冲区
- 4. Vim - 每次关闭缓冲区时停止缓冲区编号自动递增
- 5. vim和NERD树扩展 - 添加文件
- 6. Vim和NERD树 - 删除文件
- 7. 区分Vim中的隐藏缓冲区和活动缓冲区
- 8. 如何绑定q关闭Vim中的只读缓冲区?
- 9. vim在关闭后不保存缓冲区历史记录
- 10. 如何在vim中关闭缓冲区时执行命令?
- 11. 当一个缓冲区退出时vim语法关闭?
- 12. Vim关闭缓冲区但不分割窗口
- 13. 交互式关闭多个vim缓冲区?
- 14. 关闭缓冲区后显示Emacs缓冲区
- 15. vim:移动到缓冲区?
- 16. 刷新Vim缓冲区
- 17. vi,vim缓冲区溢出
- 18. emacs编译缓冲区自动关闭?
- 19. 自动关闭暂存缓冲区
- 20. 在预览窗口中打开新缓冲区时占用Vim预览窗口的自动关闭缓冲区
- 21. IO缓冲关闭
- 22. vim:获取卸载缓冲区的缓冲区号
- 23. 关闭/关闭对TCP接收缓冲区的影响
- 24. 如何关闭输入/输出缓冲区中的输入/输出缓冲区
- 25. 缓冲区没有正确的行为
- 26. 深度缓冲区未正确渲染
- 27. 正确清除键盘缓冲区
- 28. 如何正确解引用缓冲区?
- 29. vim nerd树插件和dvorak键盘布局
- 30. 如何启动VIM并自动打开NERD树?
真棒......那正是我一直在寻找 – 2010-03-19 18:56:22
thakns,伟大的工程 - 而不仅可用于NERDTree! – nihique 2011-07-30 22:45:43