如何将数组写入文件

我正在为android制作一个简单的程序，什么可以添加，读取和写入文本行到一个txt文件并显示在列表中。我得到了saveFile（）;函数将todo_items数组写入文件todo.txt。但由于某种原因，而不是显示列表中的真实文本行，它给了我数字... 例如，当我添加“喂狗，喂猫，喂鱼，喂鸟”，然后删除结果中的3d项它给了我“0,1,2”。不知道为什么。下面是函数的代码如何将数组写入文件

<?xml version="1.0" encoding="utf-8"?> 
<s:Application xmlns:fx="http://ns.adobe.com/mxml/2009" 
      xmlns:s="library://ns.adobe.com/flex/spark" 
      height="494" creationComplete="readFile()" 
      > 
<fx:Script> 
    <![CDATA[ 
     public var intTemp:int; 
     import mx.collections.ArrayCollection; 
     [Bindable] public var todo_items:ArrayCollection; 
     private function readFile():void 
     { 
      var todoFile:File =File.applicationStorageDirectory.resolvePath("todo.txt"); 


       var fs:FileStream = new FileStream(); 
       fs.open(todoFile, FileMode.READ); 
       var result:String = fs.readUTFBytes(fs.bytesAvailable); 
       var items:Array = result.split("\n"); 
       items.pop(); 
       todo_items = new ArrayCollection(items); 
       fs.close(); 

     } 
     private function writeFile():void 
     { 
      var todoFile:File = File.applicationStorageDirectory.resolvePath("todo.txt"); 


      var fs:FileStream = new FileStream(); 
      fs.open(todoFile, FileMode.APPEND); 


      fs.writeUTFBytes(task_txt.text + "\n"); 


      fs.close(); 
      readFile(); 
     } 

     private function deleteItem():void 
     {   
       var todoFile:File =File.applicationStorageDirectory.resolvePath("todo.txt"); 
       var fs:FileStream = new FileStream(); 
       fs.open(todoFile, FileMode.READ); 
       var result:String = fs.readUTFBytes(fs.bytesAvailable); 
       var items:Array = result.split("\n"); 
       items.pop(); 
       todo_items = new ArrayCollection(items); 
       todo_items.removeItemAt(intTemp); 
       fs.close(); 
       safeFile(); 
     } 
     private function safeFile():void 
     { 

      var todoFile:File = File.applicationStorageDirectory.resolvePath("todo.txt"); 


      var fs:FileStream = new FileStream(); 
      fs.open(todoFile, FileMode.WRITE); 

      for(var item:String in todo_items) 
      { 
       fs.writeUTFBytes(item + "\n") 
      } 

      fs.close(); 
      readFile(); 



     } 

    ]]> 
</fx:Script> 


<s:List id="todo_list" left="10" right="10" top="142" bottom="87" dataProvider="{todo_items}"/> 
<s:Button left="11" right="10" top="69" height="65" label="Save task" click="writeFile(); task_txt.text = null" 
      enabled="{task_txt.text.length > 0}"/> 
<s:TextInput id="task_txt" left="10" right="10" top="10" height="51" prompt="Specify a task"/> 
<s:Button left="10" right="10" bottom="14" label="Delete" 
      click="intTemp = todo_list.selectedIndex; todo_items.removeItemAt(todo_list.selectedIndex); deleteItem()" 
      enabled="{todo_list.selectedIndex != -1}"/> 


</s:Application>

来源

2012-07-25 Артем Ширяев

'todo_items'从哪里来？请给更多的代码。或至少是其声明 – poussma 2012-07-25 09:33:32

以下是完整的代码 – 2012-07-25 09:37:46

代码在哪里？ – poussma 2012-07-25 09:40:45

好，for(var item in array)套item到所有键的数组中，即0，1，2，...

为了得到实际的项目，你需要执行以下操作之一：

for(var item:String in todo_items) 
{ 
    fs.writeUTFBytes(todo_items[item] + "\n") 
}

或

for each(var item:String in todo_items) 
{ 
    fs.writeUTFBytes(item + "\n") 
}

我RECO修正第二个因为它更清洁。

来源

2012-07-25 09:43:11

谢谢收获！刚刚尝试过 - 仍然是一样的。 – 2012-07-25 09:48:57

或者也许它的Flash Builder窃听，YEESSS它的工作！非常感谢！ – 2012-07-25 09:56:58

如何将数组写入文件

回答

相关问题