为什么在F＃模式匹配中某些表达式中的泛型类型与obj相匹配？

Question

我有以下代码：

type Message<'a> = | Message of 'a 

let handleMessage message = 
    match box message with 
    | :? Message<_> -> printfn "Message" 
    | _ -> printfn "Not message" 

let handleMessageEx message = 
    match box message with 
    | :? Message<int> -> printfn "Message" 
    | _ -> printfn "Not message" 

handleMessage <| Message 1 
handleMessage <| Message (1 :> obj) 
handleMessageEx <| Message 1 

在F＃交互式输出如下：

Not message 
Message 
Message 

为什么第一条语句结果“没有消息”？即当匹配装箱值F＃无法检测到它是通用类型消息< _>并且除非我指定底层类型，否则它将其设置为对象（因此在（消息1）上失败匹配）。

Answer 1

只要你看到_作为类型参数，就把它想象成一个你不关心的新类型参数。如果我们据此调整你的第一个定义：

let handleMessage message = 
    match box message with 
    | :? Message<'_a> -> printfn "Message" 
    | _ -> printfn "Not message" 

那么编译器为我们提供了这个有用的线索：

警告FS0064：此构造导致代码比由类型注释所列的那样普通。类型变量'_a被约束为类型'obj'。

的问题是，该类型参数必须要给出一些具体的值，但是编译器上没有依据挑一个，这样它默认为obj，这是不是你想要的。

开箱即用并没有很好的方法，但您可以创建一个活动模式以简化体验：https://stackoverflow.com/a/2140485/82959。

Answer 2

简而言之，Message<_>并不意味着你期望它是通用的，这意味着编译器可以自由地推断出Message的泛型类型参数。在没有其他限制的情况下，其结果是使其成为obj。如果你做的功能一般也会发生这种情况 - 泛型类型参数的函数（以及由此延伸，以Message类型检查）在调用点决定：

let handleMessage<'a> (message: obj) = 
    match message with 
    | :? Message<'a> -> printfn "Message" 
    | _ -> printfn "Not message" 

handleMessage <| Message 1  // Not message -> 'a inferred to be obj 
handleMessage<int> <| Message 1 // Message -> 'a inferred to be int 

你可能想要做的是什么像这样：

let handleMessage message = 
    let typ = message.GetType() 
    match typ with 
    | _ when typ.GetGenericTypeDefinition() = typedefof<Message<_>> -> printfn "Message" 
    | _ -> printfn "Not message" 

handleMessage <| Message 1 
handleMessage <| Message (1 :> obj) 

这里不是做一个类型测试，而是检查两者的泛型类型定义。