在QB64中通过网络接收和发送字符串

我正在为我的兄弟工作在网络上的迷你口袋妖怪游戏。不幸的是，在测试时，我发现出于某种原因，它只在尝试向另一台计算机发送字符串的行上出现“错误的文件名或数字”错误，但在循环接收命令时没有错误。在QB64中通过网络接收和发送字符串

这里是我的代码：

SCREEN 12 
CLS 
PRINT "" 
PRINT "" 
PRINT "" 
PRINT "" 
PRINT "" 
PRINT "      POKELITE - By Mark " 
PRINT "" 
PRINT "" 
INPUT "Join or Host a game? ", hostorjoin$ 
hostorjoin$ = UCASE$(hostorjoin$) 
IF hostorjoin$ = "JOIN" THEN GOTO JOIN 
IF hostorjoin$ = "HOST" THEN GOTO HOST 

HOST: 
server& = _OPENHOST("TCP/IP:300") 
PRINT "Waiting for connection..." 
PRINT "! Remember: If playing locally, give the other player your IPv4 Address !" 
DO 
    HOST& = _OPENCONNECTION(server&) 
LOOP UNTIL HOST& <> 0 
PRINT "" 
PRINT "2nd Player Joined!" 
SLEEP 2 
GOTO GAME 
JOIN: 
INPUT "Enter Server IPv4 Address (Example: 192.168.1.25): ", joinip$ 
handle& = _OPENCLIENT("TCP/IP:300:" + joinip$) 
IF handle& = 0 THEN PRINT "Connection failed!": SLEEP 2: CLS: GOTO JOIN 
GOTO GAME 
GAME: 
CLS 
INPUT "Enter your name: ", name$ 
IF name$ = "" THEN GOTO GAME 
PRINT "Waiting for other player..." 
IF hostorjoin$ = "JOIN" THEN 
    PUT HOST&, , name$ 
    DO 
     GET handle&, , name2$ 
    LOOP UNTIL name2$ <> "" 
END IF 
IF hostorjoin$ = "HOST" THEN 
    PUT handle&, , name$ 
    DO 
     GET HOST&, , name2$ 
    LOOP UNTIL name2$ <> "" 
END IF 
PRINT name$ 
PRINT name2$

来源

2017-07-17 Mark

您需要确保端口可用，否则server&将是无效的服务器手柄。 Choosing a port of 49152 or higher is generally safe。然而，这可能不是你唯一的问题。

您的问题很可能是您的连接变量根本不相同，这意味着HOST&和handle&应该只是handle&。重要的是要记住，从来没有“主机句柄”和“客户端句柄”;唯一的句柄是“服务器句柄”（使用_OPENHOST为本地连接创建一个端口）和“连接句柄”（由服务器使用_OPENCONNECTION创建连接到客户端或_OPENCLIENT由客户端连接到服务器）。这也将减少你的逻辑，只做一个PUT，然后循环一个GET。我使用名称connection&而不是handle&，但您明白了。

SCREEN 12 
CLS 
PRINT "" 
PRINT "" 
PRINT "" 
PRINT "" 
PRINT "" 
PRINT "      POKELITE - By Mark " 
PRINT "" 
PRINT "" 
INPUT "Join or Host a game? ", hostorjoin$ 
hostorjoin$ = UCASE$(hostorjoin$) 
IF hostorjoin$ = "JOIN" THEN GOTO JOIN 
IF hostorjoin$ = "HOST" THEN GOTO HOST 
' If neither "HOST" nor "JOIN" is specified, what happens? 

HOST: 
server& = _OPENHOST("TCP/IP:300") 
PRINT "Waiting for connection..." 
PRINT "! Remember: If playing locally, give the other player your IPv4 Address !" 
DO 
    connection& = _OPENCONNECTION(server&) 
LOOP UNTIL connection& <> 0 
PRINT "" 
PRINT "2nd Player Joined!" 
SLEEP 2 
GOTO GAME 
JOIN: 
INPUT "Enter Server IPv4 Address (Example: 192.168.1.25): ", joinip$ 
connection& = _OPENCLIENT("TCP/IP:300:" + joinip$) 
IF connection& = 0 THEN PRINT "Connection failed!": SLEEP 2: CLS: GOTO JOIN 
GOTO GAME 
GAME: 
CLS 
INPUT "Enter your name: ", playerName$ 
IF playerName$ = "" THEN GOTO GAME 
PRINT "Waiting for other player..." 

' Send name to opponent and wait for opponent's name. 
PUT connection&, , playerName$ 
DO 
    GET connection&, , opponentName$ 
LOOP UNTIL opponentName$ <> "" 

PRINT "You:  "; playerName$ 
PRINT "Opponent:"; opponentName$

来源

2017-07-20 21:14:15

在QB64中通过网络接收和发送字符串

回答

相关问题