如何正确转换日期时间和时区？

我已经做了一些搜索，我不知道如何使用核心Perl模块正确地转换它。我有2013-10-22T19:31:00Z，想要获得10/22/2013和美国中部时间。如何正确转换日期时间和时区？

2013-10-22 BluGeni

对于使用核心模块转换日期/时间格式，请参阅[此SO问题]（http://stackoverflow.com/questions/17037539/perl-convert-date-timezone-without-datetime-module）等。 – ThisSuitIsBlackNot

@ThisSuitIsBlack不，没有足够的信息来回答他在这个问题的答案中的问题。 – ikegami

@ikegami然而，有一个链接到Time :: Piece的文档，这将是一个好的开始。 – ThisSuitIsBlackNot

标准Perl模块？

这将包括从5.10开始已经成为Perl的一部分的Time::Piece。

#! /usr/bin/env perl 

use strict; 
use warnings; 
use feature qw(say); 
use Time::Piece; 

my $date = "2013-10-22T19:31:00Z"; 

my $time = Time::Piece->strptime ($date, "%Y-%m-%dT%H:%M:%SZ"); 
$time = localtime($time); # Converts time to local time 

say $time->mdy("/");

此打印出：

10/22/2013

那古怪"%Y-%m-%dT%H:%M:%SZ"字符串代表你的时间输入格式。您可以在strftime的管理中找到它。

%Y：四位数表示的年份
%m：月从01 - 12
%d：日从01 - 31
%H：小时，从00 - 23
%M：从00分钟 - 59
%S：第二个从00到59

来源

2013-10-22 22:24:05

这不会转换为中央时间 – ikegami

我已经添加了一个'localtime'函数。这会将'$ time'对象转换为本地时间而不是GMT。如果您当地的时间是中央时间，这将起作用。也许真正的答案是使用[Slaven's]（http://stackoverflow.com/a/19528445/368630）设置'$ ENV {TZ}变量并运行'tzset'的技巧。 –

use DateTime::Format::RFC3339 qw(); 
use DateTime::Format::Strptime qw(); 

my $in_dt_format = DateTime::Format::RFC3339->new(); 

my $out_dt_format = DateTime::Format::Strptime->new(
    pattern => '%m/%d/%Y %H:%M:%S', 
    on_error => 'croak', 
); 

my $dt = $in_dt_format->parse_datetime('2013-10-22T19:31:00Z'); 
$dt->set_time_zone('America/Chicago'); 
say $out_dt_format->format_datetime($dt); # 10/22/2013 14:31:00

来源

2013-10-22 19:51:14 ikegami

我没有第一个模块'无法找到日期时间/格式/ RFC3339.pm' – BluGeni

@BluGeni，所以安装它。 – ikegami

不适合我，不幸的是。这就是为什么我说我只需要一些核心Perl模块 – BluGeni

这里只用核心模块的解决方案（当然，你需要有至少Perl的5.8）：

use strict; 
use POSIX qw(tzset strftime); 
use Time::Local qw(timegm); 

my $iso_time = "2013-10-22T19:31:00Z"; 
my $formatted_time; 
{ 
    local $ENV{TZ} = "America/Chicago"; 
    tzset; 
    if (my($y,$m,$d,$H,$M,$S) = $iso_time =~ m{^(\d{4})-(\d{2})-(\d{2})T(\d{2}):(\d{2}):(\d{2})Z$}) { 
     $formatted_time = strftime '%m/%d/%Y %H:%M:%S', localtime timegm $S,$M,$H,$d,$m-1,$y; 
    } else { 
     # invalid ISO date, do something 
    } 
} 
tzset; # restore default time zone handling 

warn $formatted_time, "\n"; # output is "10/22/2013 14:31:00"

有关TZ招一个字：通过设置环境变量TZ一些时间相关的libc函数（例如localtime）使用该时区而不是默认时区。如果在程序中设置了TZ环境变量，则必须调用tzset()来调整与内部时间相关的数据结构。并且不要忘记再次调用tzset()来重新恢复数据结构。

这应该适用于大多数Unix系统，但可能在Windows系统上运行，也可能不运行。

来源

2013-10-22 21:11:27

如何正确转换日期时间和时区？

回答

相关问题