在一个范围内的每个单元格周围的边框

我想创建一个简单的功能，将在一定范围内的每个单元格周围添加边框。使用精彩的录音会产生大量无用的代码。下面的代码将显示一个“表格”的数据，在这个范围内的每个单元格周围，我想添加一个边框。在线我一直无法找到一个简单或明确的答案。在一个范围内的每个单元格周围的边框

所有帮助非常感谢！

Set DT = Sheets("DATA") 
endRow = DT.Range("F" & Rows.Count).End(xlUp).Row 
result = 3 

For I = 2 To endRow 
    If DT.Cells(I, 6).Value = Range("B1").Value Then 
     Range("A" & result) = DT.Cells(I, 6).Value 
     Range("B" & result) = DT.Cells(I, 1).Value 
     Range("C" & result) = DT.Cells(I, 24).Value 
     Range("D" & result) = DT.Cells(I, 37).Value 
     Range("E" & result) = DT.Cells(I, 3).Value 
     Range("F" & result) = DT.Cells(I, 15).Value 
     Range("G" & result) = DT.Cells(I, 12).Value 
     Range("H" & result) = DT.Cells(I, 40).Value 
     Range("I" & result) = DT.Cells(I, 23).Value 
     result = result + 1 
    End If 
Next I

来源

2012-10-29 CustomX

我编辑我的头衔视为尽管它迷惑人。 – CustomX

你只需要一个单一的代码行设置范围内每个单元格周围的边框：

Range("A1:F20").Borders.LineStyle = xlContinuous

对每个单元格周围的边框应用多种效果也很容易。

例如：

Sub RedOutlineCells() 
    Dim rng As Range 

    Set rng = Range("A1:F20") 

    With rng.Borders 
     .LineStyle = xlContinuous 
     .Color = vbRed 
     .Weight = xlThin 
    End With 
End Sub

来源

2012-10-29 21:53:51

对于添加边框尝试这个，例如：

Range("C11").Borders(xlEdgeRight).LineStyle = xlContinuous 
Range("A15:D15").Borders(xlEdgeBottom).LineStyle = xlContinuous

希望这种语法是正确的，因为我已经在C＃中做到了这一点。

来源

2012-10-29 12:41:57 Sylca

没有什么帮助，这可以在一个范围内工作，但不是每个单元格。 – CustomX

，究竟是什么：Range（“C11”）。Borders（xlEdgeRight）.LineStyle = xlContinuous or this：Range（“A15：A15”）。Borders（xlEdgeBottom）.LineStyle = xlContinuous – Sylca

Idk这就是你'我在最初的代码中没有提供任何东西。 – CustomX

下可以用任何范围内，参数被称为：

Option Explicit 

Sub SetRangeBorder(poRng As Range) 
    If Not poRng Is Nothing Then 
     poRng.Borders(xlDiagonalDown).LineStyle = xlNone 
     poRng.Borders(xlDiagonalUp).LineStyle = xlNone 
     poRng.Borders(xlEdgeLeft).LineStyle = xlContinuous 
     poRng.Borders(xlEdgeTop).LineStyle = xlContinuous 
     poRng.Borders(xlEdgeBottom).LineStyle = xlContinuous 
     poRng.Borders(xlEdgeRight).LineStyle = xlContinuous 
     poRng.Borders(xlInsideVertical).LineStyle = xlContinuous 
     poRng.Borders(xlInsideHorizontal).LineStyle = xlContinuous 
    End If 
End Sub

例子：

Call SetRangeBorder(Range("C11")) 
Call SetRangeBorder(Range("A" & result)) 
Call SetRangeBorder(DT.Cells(I, 6)) 
Call SetRangeBorder(Range("A3:I" & endRow))

来源

2012-10-29 13:26:52

这里的另一种方式

Sub testborder() 

    Dim rRng As Range 

    Set rRng = Sheet1.Range("B2:D5") 

    'Clear existing 
    rRng.Borders.LineStyle = xlNone 

    'Apply new borders 
    rRng.BorderAround xlContinuous 
    rRng.Borders(xlInsideHorizontal).LineStyle = xlContinuous 
    rRng.Borders(xlInsideVertical).LineStyle = xlContinuous 

End Sub

来源

2012-10-29 19:21:04

没有找到这个页面，当我最初找这个问题，但这里是我的最终结果。诚实地抬起头，张贴在超级用户，但不知道是否属于那里或这里。

样品呼叫

Call BoxIt(Range("A1:z25"))

子程序

Sub BoxIt(aRng As Range) 
On Error Resume Next 

    With aRng 

     'Clear existing 
     .Borders.LineStyle = xlNone 

     'Apply new borders 
     .BorderAround xlContinuous, xlThick, 0 
     With .Borders(xlInsideVertical) 
      .LineStyle = xlContinuous 
      .ColorIndex = 0 
      .Weight = xlMedium 
     End With 
     With .Borders(xlInsideHorizontal) 
      .LineStyle = xlContinuous 
      .ColorIndex = 0 
      .Weight = xlMedium 
     End With 
    End With 

End Sub

来源

2016-03-25 21:38:32 Crazyd

xlWorkSheet.Cells(1, 1).Borders(Excel.XlBordersIndex.xlEdgeRight).LineStyle = Excel.XlDataBarBorderType.xlDataBarBorderSolid 
xlWorkSheet.Cells(1, 1).Borders(Excel.XlBordersIndex.xlEdgeLeft).LineStyle = Excel.XlDataBarBorderType.xlDataBarBorderSolid 
xlWorkSheet.Cells(1, 1).Borders(Excel.XlBordersIndex.xlEdgeBottom).LineStyle = Excel.XlDataBarBorderType.xlDataBarBorderSolid 
xlWorkSheet.Cells(1, 1).Borders(Excel.XlBordersIndex.xlEdgeTop).LineStyle = Excel.XlDataBarBorderType.xlDataBarBorderSolid

来源

2017-01-03 07:34:31

在一个范围内的每个单元格周围的边框

回答

相关问题