vb.net如何制作只有notifyicon和没有窗体的应用程序？

Question

我想创建一个只有notifyicon的应用程序，它在启动时没有任何可见的窗体。我看到一些例子，比如我想为c＃做什么，但是我不知道如何在vb.net项目中做到这一点。

Answer 1

形式是不是绝对必要的。您可以实例化的NotifyIcon和使用，而无需创建一个表单：

Public Class AppContext 
    Inherits ApplicationContext 

    Private notifyIcon As NotifyIcon 
    Private appActive As Boolean 

    Public Sub New() 
     AddHandler Application.ApplicationExit, AddressOf OnApplicationExit 

     notifyIcon = New NotifyIcon() 
     notifyIcon.Icon = My.Resources.ActiveIcon 
     notifyIcon.Text = "The app is active." 

     AddHandler notifyIcon.MouseClick, AddressOf OnIconMouseClick 

     appActive = True 
     notifyIcon.Visible = True 

    End Sub 

    Private Sub OnApplicationExit(ByVal sender As Object, ByVal e As EventArgs) 
     If notifyIcon IsNot Nothing Then 
      notifyIcon.Dispose() 
     End If 
    End Sub 

    Private Sub OnIconMouseClick(ByVal sender As Object, ByVal e As MouseEventArgs) 

     If e.Button = MouseButtons.Left Then 
      appActive = Not appActive 
      notifyIcon.Icon = If(appActive, My.Resources.ActiveIcon, My.Resources.InactiveIcon) 
      notifyIcon.Text = If(appActive, "The app is active.", "The app is not active.") 
     Else 
      If MsgBox("Do you want to Exit?", MsgBoxStyle.YesNo) = MsgBoxResult.Yes Then 
       notifyIcon.Visible = False 
       ExitThread() 
      End If 
     End If 
    End Sub 

End Class 

，然后开始从子主你的应用程序：

Public Module EntryPoint 
    Public Sub Main() 
     Dim ctx As New AppContext() 
     Application.Run(ctx) 
    End Sub 
End Module 

Answer 2

只要把形式透明，并将其调整到1×1 .. 并添加NotifyIcon的..

而且在窗体的Load事件做到这一点：

NotifyIcon.Visible =真

然后做任何你想要的东西..

你可以创建一个上下文菜单条（当你右键点击它时的一个菜单） PS：如果你这样做，你需要去NotifyIcon属性并设置上下文菜单条您创建..

希望它可以帮助你..