亚当史密斯的回答已经解释了为什么你会得到“instance235”,所以我将解释stage
对象的name
属性等于null的解决方法。
您可以为stage
对象创建包装类,并为该类提供一个名为name
的属性。包装类也必须是EventDispatcher
的子类,以便您可以重写它的addEventListener()
方法并更改其功能,以便隐式地将事件侦听器添加到舞台对象以及包装器对象。解释它的最好办法是告诉你我做了一个例子:
package
{
import flash.display.DisplayObject;
import flash.display.Sprite;
import flash.events.Event;
import flash.events.MouseEvent;
public class Main extends Sprite
{
private var _stageWrapper:StageWrapper;
public function Main():void
{
if (stage) init();
else addEventListener(Event.ADDED_TO_STAGE, init);
}// end function
private function init(e:Event = null):void
{
removeEventListener(Event.ADDED_TO_STAGE, init);
var stageWrapper:StageWrapper = new StageWrapper(stage, "stage");
stageWrapper.addEventListener(MouseEvent.CLICK, onStageWrapperClick);
}// end function
private function onStageWrapperClick(e:MouseEvent):void
{
trace(e.target.name) // output: stage
}// end function
}// end class
}// end package
import flash.display.Stage;
import flash.events.Event;
import flash.events.EventDispatcher;
import flash.events.MouseEvent;
internal class StageWrapper extends EventDispatcher
{
private var _stage:Stage;
private var _name:String;
private var _listener:Function;
public function get stage():Stage { return _stage }
public function get name():String { return _name }
public function StageWrapper(stage:Stage, name:String)
{
_stage = stage;
_name = name;
}// end function
override public function addEventListener(type:String,
listener:Function,
useCapture:Boolean = false,
priority:int = 0,
useWeakReference:Boolean = false):void
{
super.addEventListener(type, listener, useCapture, priority, useWeakReference);
_stage.addEventListener(type, onStageEvent, useCapture, priority, useWeakReference);
}// end function
private function onStageEvent(e:Event):void
{
dispatchEvent(e);
}// end function
}// end class
个人而言,我不会用这种方法去,但这个是最好的答案我可以给你方向,你似乎要与去。
好的,我很抱歉... mcSlideHolder有1个孩子,那个“instance235”就是那个孩子。这是一个位图对象... – haemse 2011-05-19 19:30:30
不是将目标显示对象的name属性的值与字符串值进行比较,而是将目标显示对象直接与另一个显示对象进行比较。例如,不是测试'e.target.name == null',而是测试'e.target == stage'。 – Taurayi 2011-05-19 20:22:44
重复的问题http://stackoverflow.com/questions/6062339/as3-click-event-added-to-stage-but-fires-when-clicking-on-a-movieclick – 2011-05-19 21:07:48