Excel报告 - 公式VBA

Question

我在使用VB6构建报告时遇到了一些问题。基本上，我正在构建一个动态报告，其中标题和2列（客户端，学生）从记录集中填充。正如您在图片中看到的，在我的标题末尾，我添加了一个TOTAL标题，下面有客户和学生。我试图让每个专栏中的所有客户总数达到TOTAL，与学生一样。列数（UCLA，SDU，SCCU）可能会有所不同，所以我试图让它变成动态的。基本上从A开始，然后是B，然后是C，D和NONE。有任何想法吗？ 编辑：我请从SQL SERVER的SHORT LABEL和填充直到g_RS3是空

Do While Not g_RS3.EOF 
    With xlSheet.Cells(xlRow, xlCol) 
     .Value = g_RS3("ShortLabel") 
      .Offset(1, 0).Value = " Clients " 
      .Offset(1, 1).Value = " Students" 
       With .Offset(1, 0) 
        .Font.Bold = True 
       .Borders.Weight = xlThin 
      End With 
      With .Offset(1, 1) 
       .Font.Bold = True 
       .Borders.Weight = xlThin 
      End With 
      With .Resize(1, 2) 
       .Font.Bold = True 
       .WrapText = True 
       .VerticalAlignment = xlCenter 
       .Merge 
       .HorizontalAlignment = xlCenter 
       .Borders.Weight = xlThin 
      End With 
    End With 
    xlCol = xlCol + 2 
    g_RS3.MoveNext 
Loop 
With xlSheet.Cells(xlRow, xlCol) 
    .Value = "TOTAL" 
     .Offset(1, 0).Value = "Clients" 
     .Offset(1, 1).Value = "Students" 
      With .Offset(1, 0) 
       .Font.Bold = True 
      .Borders.Weight = xlThin 
     End With 
     With .Offset(1, 1) 
      .Font.Bold = True 
      .Borders.Weight = xlThin 
     End With 
     With .Resize(1, 2) 
      .Font.Bold = True 
      .WrapText = True 
      .VerticalAlignment = xlCenter 
      .Merge 
      .HorizontalAlignment = xlCenter 
      .Borders.Weight = xlThin 
     End With 
End With 

然后我开始xlrow = 4 xlcol = 2和填充数据在客户端和STUDENT列。我拥有的循环相当长。但用户只会查看摘录。一旦它的产生取决于他们，他们用它做什么。该应用程序为他们提供了添加SHORTLABEL的选项，一旦它们生成，SHORTLABEL需要在提取中显示。

Answer 1

SUMIF function或SUMIFS function可以方便地执行此操作。

在H4作为标准公式，

=sumifs($b4:$g4, $b$3:$g$3, h$3) 

填写两个向右和向下。

在VBA作为，

with worksheets("Sheet1") 
    .range("H4:I8").formula = "=sumifs($b4:$g4, $b$3:$g$3, h$3)" 
    'optional revert to values only 
    '.range("H4:I8") = .range("H4:I8").values 
end with 

您必须确定客户端/学生的程度范围，但有一半做法仅仅是知道放在哪里公式（例如H4）。

VBA

我已经删除了很多所使用的原代码的冗余。考虑到您尚未将数据填充到客户端/学生列中，我使用了一种方法，其中Total列（s）总是写入右侧的公式。如果还有另外一组行，那么总计将被覆盖，并在右侧创建一个新行。

Dim xlStartCol As Long 
xlStartCol = xlCol 
Do While Not g_RS3.EOF 
    With xlSheet.Cells(xlRow, xlCol) 
     .Resize(1, 2).Merge 
     .Value = "TEST" 'g_RS3("ShortLabel") 
     .Offset(1, 0).Resize(1, 2) = Array("Clients", "Students") 
     .Offset(2, 0).Resize(1, 2).ClearContents 
     With .Offset(0, 1) 
      .Resize(1, 2).Merge 
      .Value = "Total" 'keep writing Total to the right; it will be overwritten if there is another ShortLabel 
      .Offset(1, 0).Resize(1, 2) = Array("Clients", "Students") 
      .Offset(2, 0).Resize(1, 2).Formula = _ 
       "=SUMIFS(" & Range(.Parent.Cells(xlRow + 2, xlStartCol), .Parent.Cells(xlRow + 2, xlCol + 1)).Address(0, 1) & Chr(44) & _ 
          Range(.Parent.Cells(xlRow + 1, xlStartCol), .Parent.Cells(xlRow + 1, xlCol + 1)).Address(1, 1) & Chr(44) & _ 
          .Parent.Cells(xlRow + 1, xlCol - 1).Address(1, 0) & Chr(41) 
     End With 
     With .Resize(2, 4) 
      .Font.Bold = True 
      .VerticalAlignment = xlCenter 
      .HorizontalAlignment = xlCenter 
      .Borders.Weight = xlThin 
     End With 
    End With 
    xlCol = xlCol + 2 
    g_RS3.MoveNext 
Loop 

一旦实际填充数据到每对列和了解程度，只需使用Range.FillDown method来填充剩下的公式。

我会建议删除不相关的记录代码部分。记录的代码非常冗长，妨碍了可读性。您可能还想查看在T-SQL中创建查询的For XML方法。这将扩展返回的列，并允许您使用字段计数来确定范围。