通过调度程序作业将参数传递给oracle存储过程

Question

我有一个正在从dbms作业调用的存储过程。即

DBMS_SCHEDULER.RUN_JOB ('Procedure_JB', FALSE); 

java代码存储过程，它做了一些事情后，异步启动Procedure_JB。然后这个Procedure_JB调用Procedure_PRogram，然后程序会调用存储过程。

如何将参数传递给我的存储过程？

• 我必须传递给作业的参数来自java。

Answer 1

定义您的工作Procedure_JB接受参数。然后使用dbms_scheduler.set_job_argument_value来定义要传递到您的作业要运行的程序中的参数的值。一个例子（取自https://forums.oracle.com/forums/thread.jspa?threadID=483135）

-- create a stored procedure with two arguments 
create or replace procedure myproc (arg1 in varchar2, arg2 in varchar2) 
is BEGIN null; END; 
/

-- create a program with two arguments and define both 
begin 
dbms_scheduler.create_program 
(
program_name=>'myprog', 
program_action=>'myproc', 
program_type=>'STORED_PROCEDURE', 
number_of_arguments=>2, enabled=>FALSE 
) ; 

dbms_scheduler.DEFINE_PROGRAM_ARGUMENT(
program_name=>'myprog', 
argument_position=>1, 
argument_type=>'VARCHAR2', 
DEFAULT_VALUE=>'13'); 

dbms_scheduler.DEFINE_PROGRAM_ARGUMENT(
program_name=>'myprog', 
argument_position=>2, 
argument_type=>'VARCHAR2'); 

dbms_scheduler.enable('myprog'); 
end; 
/

-- create a job pointing to a program and set both argument values 
begin 
dbms_scheduler.create_job('myjob',program_name=>'myprog'); 
dbms_scheduler.set_job_argument_value('myjob',1,'first arg'); 
dbms_scheduler.set_job_argument_value('myjob',2,'second arg'); 
dbms_scheduler.enable('myjob'); 
end; 
/