VBA集合：密钥列表

Question

在向VBA集合添加一些值之后，有没有办法保留所有密钥的列表？

例如

Dim coll as new Collection 
Dim str1, str2, str3 
str1="first string" 
str2="second string" 
str3="third string" 
coll.add str1, "first key" 
coll.add str2, "second key" 
coll.add str3, "third key" 

我知道如何保留字符串列表：再次

first string 
second string 
third string 

：有什么办法留住钥匙？

first key 
second key 
third key 

注：我使用VBA通过AutoCAD 2007的

Answer 1

我不认为可能与香草集合，没有一个独立的存储阵列中的键值。最简单的替代方法是添加对Microsoft脚本运行时的引用&而不是使用更强大的字典;

Dim coll As New Dictionary 
... 
Dim K As Variant 
For Each K In coll.Keys 
    debug.print "Key: " & K , "Value: " & coll.Item(K) 
Next 

Answer 2

如果您打算使用默认VB6 Collection，那么你可以做最简单的就是：

col1.add array("first key", "first string"), "first key" 
col1.add array("second key", "second string"), "second key" 
col1.add array("third key", "third string"), "third key" 

然后你可以列出所有值：

Dim i As Variant 

For Each i In col1 
    Debug.Print i(1) 
Next 

个或所有密钥：

Dim i As Variant 

For Each i In col1 
    Debug.Print i(0) 
Next 

Answer 3

另一种解决方案是将密钥存储在单独的收集：

'Initialise these somewhere. 
Dim Keys As Collection, Values As Collection 

'Add types for K and V as necessary. 
Sub Add(K, V) 
Keys.Add K 
Values.Add V, K 
End Sub 

您可以维护的键和值，这可能是有用的，有时单独的排序顺序。

Answer 4

您可以创建一个小类来保存键和值，然后将该类的对象存储在集合中。

类KEYVALUE：

Public key As String 
Public value As String 
Public Sub Init(k As String, v As String) 
    key = k 
    value = v 
End Sub 

然后使用它：

Public Sub Test() 
    Dim col As Collection, kv As KeyValue 
    Set col = New Collection 
    Store col, "first key", "first string" 
    Store col, "second key", "second string" 
    Store col, "third key", "third string" 
    For Each kv In col 
     Debug.Print kv.key, kv.value 
    Next kv 
End Sub 

Private Sub Store(col As Collection, k As String, v As String) 
    If (Contains(col, k)) Then 
     Set kv = col(k) 
     kv.value = v 
    Else 
     Set kv = New KeyValue 
     kv.Init k, v 
     col.Add kv, k 
    End If 
End Sub 

Private Function Contains(col As Collection, key As String) As Boolean 
    On Error GoTo NotFound 
    Dim itm As Object 
    Set itm = col(key) 
    Contains = True 
MyExit: 
    Exit Function 
NotFound: 
    Contains = False 
    Resume MyExit 
End Function 

这是当然类似于字典建议，除没有任何外部依赖性。如果你想存储更多的信息，这个类可以根据需要变得更加复杂。

Answer 5

麻烦的是，对于大型数据集，集合执行方式比任何字典更好...