Perl Class ::访问失败，简单的例子 - 为什么？

Question

有人能告诉我为什么在这个非常小而平凡的例子中，main没有找到Class :: Accessor生成的方法吗？

的这几行代码失败，

perl codesnippets/accessor.pl 
Can't locate object method "color" via package "Critter" at 
codesnippets/accessor.pl line 6. 

看到代码：

#!/opt/local/bin/perl 
# The whole Class::Accessor thing does not work !! 

my $a = Critter->new; 
$a->color("blue"); 
$a->display; 
exit 0; 

package Critter; 
    use base qw(Class::Accessor); 
    Critter->mk_accessors ("color"); 

    sub display { 
     my $self = shift; 
     print "i am a $self->color " . ref($self) . ", whatever this word means\n"; 
    } 

Answer 1

FM给你很好的建议。需要在其他代码之前运行mk_accessors。另外，通常你会把Critter放在一个单独的文件中，并且use Critter加载模块。

这是可行的，因为use具有编译时间效果。做use Critter;和做BEGIN { require Critter; Critter->import; }是一样的。这保证你的模块的初始化代码在代码的其余部分编译之前运行。

将多个包放入一个文件是可以接受的。通常情况下，我会将相关对象的原型制作在一个文件中，因为它可以在我进行原型设计时保持一切便利。随着时间的推移，将文件分成不同的位也很容易。因此，我发现将多个包保存在一个文件中，并像使用它们一样处理它们的最佳方式是将包定义放在以真值结束的BEGIN块中。用我的方法，你的榜样将写成：

#!/opt/local/bin/perl 

my $a = Critter->new; 
$a->color("blue"); 
$a->display; 

BEGIN { 
    package Critter; 
    use base qw(Class::Accessor); 

    use strict; 
    use warnings; 

    Critter->mk_accessors ("color"); 

    sub display { 
     my $self = shift; 

     # Your print was incorrect - one way: 
     printf "i am a %s %s whatever this word means\n", $self->color, ref $self; 

     # another: 
     print "i am a ", $self->color, ref $self, "whatever this word means\n"; 

    } 

    1; 
} 

Answer 2

你的代码是乱序。如果你想要color访问器可用，你需要在之前调用mk_accessors你创建你的对象，并开始做它的东西。例如：

package Critter; 
use base qw(Class::Accessor); 
Critter->mk_accessors("color"); 

sub display { 
    my $self = shift; 
    print $self->color, ' ', ref($self), "\n"; 
} 

package main; 
my $c = Critter->new; 
$c->color("blue"); 
$c->display; 

更常见的是，Critter代码将其自身的模块（Critter.pm）中，且所有的mk_accessor魔术会发生，当你的主要脚本运行use Critter - 你的脚本开始与Critter行之有效前和Varmint对象。

Answer 3

我只是想为您提供更好的解决方案 - 如果解不欢迎随时downvote这个被遗忘，但是C :: A是真是一个糟糕的主意这个时代，使用Moose：

package Critter; 
use Moose; 

has 'color' => (isa => 'Str', is => 'rw'); # Notice, this is typed 

sub display { 
    my $self = shift; 
    printf (
     "i am a %s %s whatever this word means\n" 
     , $self->color 
     , $self->meta->name 
    ); 
} 

package main; 
use strict; 
use warnings; 

my $c = Critter->new; # or my $c = Critter->new({ color => blue }); 
$c->color("blue"); 
$c->display;