actionscript 3跟踪动态文本更改

Question

有没有办法“聆听”动态文本？我在舞台上有这个动态文本框，并且我想在动态文本被更改后调用一个功能。我试图添加事件监听器，但它似乎只适用于INPUT文本。有什么建议么？ 谢谢

Answer 1

您是否尝试过CHANGE活动？它应该适用于所有类型的TextField，包括非输入类型。

Answer 2

正如你所说，只有输入文本发送CHANGE事件。你必须解决它，也许是这样的：

var oldText:String = ""; 

function changeEnterFrame (e:Event) { 
    if (oldText != textField.text) { 
     // Do your stuff here 
    } 
    oldText = textField.text; 
} 

addEventListener(Event.ENTER_FRAME, changeEnterFrame); 

Answer 3

虽然@ annonymously的答案作品，重视enterFrame事件听众等待文本改变（或任何改变，对于这个问题）是不是一个好主意 - 中文本可能根本不会改变，那么为什么你会每秒多次运行一段代码，如果它可以避免的话？更不用说，事实上，你必须一遍又一遍地为每一个你想要监视的新文本字段实例。

最好对实际变化做出反应，这些变化是由您自己设置的属性引起的。您应该简单地扩展了TextField类，并重写setter方法的htmlText和/或文字派遣更改事件：

override public function set text (text : String) : void { 
    super.text = text; 
    dispatchEvent (new Event (Event.CHANGE); 
} 

Answer 4

你可以写很简单的子类，可以让你听文本更改事件。

Sublass：

package 
{ 
    import flash.events.Event; 
    import flash.text.TextField; 

    public class CustomTextField extends TextField 
    { 
     public function CustomTextField() 
     { 
      super(); 
     } 

     override public function set text(value:String):void 
     { 
      if(super.text != value) 
      { 
       super.text = value; 
       dispatchEvent(new Event(Event.CHANGE, true)); 
      } 
     } 
    } 
} 

用例：

package 
{ 
    import flash.display.Sprite; 
    import flash.events.Event; 
    import flash.events.MouseEvent; 

    public class CustomTextFieldTest extends Sprite 
    { 
     private var tf:CustomTextField; 

     public function CustomTextFieldTest() 
     { 
      tf = new CustomTextField(); 

      tf.x = tf.y = 10; 
      tf.width = tf.height = 200; 

      tf.addEventListener(Event.CHANGE, onTfChange); 
      addChild(tf); 

      stage.addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown); 
     } 

     private function onTfChange(e:Event):void { 
      trace("text changed, new text: '" + tf.text + "'"); 
     } 

     private function onMouseDown(e:MouseEvent):void { 
      tf.text = "some random text: " + Math.round(100 * Math.random()); 
     } 
    } 
}