PROC TABULATE独立于数据的重新排列标题子组

Question

这是后续到previous question，它仅考虑具有两个子组的单个变量。在这个问题中，解决方案是通过排序数据来排序子组。

但是，这种方法在存在多个变量时发生故障。它变成了将变量分类成产生期望结果的序列的重要组成部分。每个后续BY变量子组取决于以前的级别。如果不是所有的子组都存在于更高级别的组中，则不是所有的子组都可以按照期望的顺序排列。

PROC TABULATE不是用于此任务的适当工具（即获得多个变量的各种组的百分比），或者存在允许子组独立于数据排列的技术。

我是否要在文档草垛中挖针，还是要重新发明轮子？任何你可以给我的见解将不胜感激。

---

实施例：

为了给出一个例子，说我想创建一个表与布置在（Y，N）顺序中的每个变量的子组。请注意，var4未按正确的顺序输出。在排序其他变量时，没有足够的值存在以按期望的顺序排序。

data example; 
    input group $ var1 $ var2 $ var3 $ var4 $; 
    datalines; 
    1 Y Y N Y 
    1 N Y N N 
    2 Y N Y N 
    2 Y Y Y N 
    3 N N N Y 
    3 N Y Y N 
    ; 
run; 

proc sort data = example out = sorted; 
    by descending var1 
     descending var2 
     descending var3 
     descending var4 
     ; 
run; 

title 'Percent'; 
proc tabulate data = sorted order = data; 
    class group var1 var2 var3 var4; 
    table group='Group', 
      all = 'Total'*pctn='' 
      var1 = 'Variable 1'*pctn='' 
      var2 = 'Variable 2'*pctn='' 
      var3 = 'Variable 3'*pctn='' 
      var4 = 'Variable 4'*pctn=''; 
run; 

它可能会设计出BY变量，其中得到（Y，N）子分组顺序PROC SORT组合，但它会涉及一串摆弄的这是不针对鲁棒数据的变化。如果表格需要每月更新一次，那么每个月你都必须摆弄排序。

Answer 1

没有解决方法或重塑所需的车轮 - 这正是classdata数据集为：

data example; 
    input group (var1-var4) ($1. +1); 
    datalines; 
    1 Y Y N Y 
    1 N Y N N 
    2 Y N Y N 
    2 Y Y Y N 
    3 N N N Y 
    3 N Y Y N 
    ; 
run; 

data classtypes; 
    do group = 1 to 3; 
     do var1 = 'Y','N'; 
      do var2 = 'Y','N';  
       do var3 = 'Y','N';     
        do var4 = 'Y','N'; 
         output; 
        end; 
       end; 
      end; 
     end;    
    end; 
run; 

title 'Percent'; 
proc tabulate data = example order = data classdata=classtypes; 
    class group var1 var2 var3 var4; 
    table group='Group', 
      all = 'Total'*pctn='' 
      var1 = 'Variable 1'*pctn='' 
      var2 = 'Variable 2'*pctn='' 
      var3 = 'Variable 3'*pctn='' 
      var4 = 'Variable 4'*pctn=''; 
run; 

作为奖励，这也避免了梳理你的主要输入数据集 - 行/列顺序输出表由classdata数据集的顺序决定。