vim omnicomplete与shift-tab不工作？

Question

我试图让vim让我通过tab键自动填充弹出列表。它适用于标签，但不适用于s-tab（shift-tab）。 看起来像shift-tab某种程度上取消了应用C-P之前的自动完成菜单

任何人有任何想法？

function InsertTabWrapper(direction) 
    if pumvisible() 
    if "forward" == a:direction 
     return "\<C-N>" 
    else 
     return "\<C-P>" 
    endif 
    endif 
    let col = col('.') - 1 
    if !col || getline('.')[col - 1] !~ '\k' 
    return "\<tab>" 
    else 
    return "\<c-x>\<c-o>" 
    endif 
endfunction 

inoremap <tab> <c-r>=InsertTabWrapper("forward")<cr> 
inoremap <s-tab> <c-r>InsertTabWrapper("backward")<cr> 

Answer 1

您<c-r>为<s-tab>映射后错过了等号 “=”。

不过，我建议做这样的：

function! InsertTabWrapper() 
    if pumvisible() 
    return "\<c-n>" 
    endif 
    let col = col('.') - 1 
    if !col || getline('.')[col - 1] !~ '\k' 
    return "\<tab>" 
    else 
    return "\<c-x>\<c-o>" 
    endif 
endfunction 
inoremap <expr><tab> InsertTabWrapper() 
inoremap <expr><s-tab> pumvisible()?"\<c-p>":"\<c-d>" 

1. 使用<expr>映射。这是更好看，更清晰的（很多人不知道<c-r>=事情
2. 映射<s-tab>这样，你可以在插入模式做取消缩进