如何在不同的串行器之间共享Dancer2应用程序之间的会话数据？

Question

我正在尝试将一个应用程序从Dancer迁移到Dancer2。我的想法是将代码分离为使用模板和Ajax（API）调用的路由。

我的基本程序是：

use strict; 
use warnings; 
use FindBin; 
use Plack::Builder; 

use Routes::Templates; 
use Routes::Login; 

builder { 
    mount '/' => Routes::Templates->to_app; 
    mount '/api' => Routes::Login->to_app; 
}; 

我在想，在Routes::Templates包不会有任何串行和Routes::Login包将有JSON序列化。我用

set serializer => 'JSON'; 

在Routes::Login包。

不过，我也希望这些共享会话数据，使每个人都有每个文件中常见的应用程序的名字

use Dancer2 appname => 'myapp'; 

。这似乎与串行化遇到麻烦。 Routes::Template路由未正确返回，因为它试图将其编码为JSON。这里的错误：

Failed to serialize content: hash- or arrayref expected (not a simple scalar, use allow_nonref to allow this)

我读过的所有文件，其中包括：

• How can I use Dancer2::Plugin::Database when my code is split into multiple files?
• https://github.com/wyoung/advent-calendar/tree/master/danceradvent/public/articles/2015

但我仍然没有就如何串行明确被包分开。

Answer 1

有没有必要结合您的应用程序使用appname;只要两个应用程序对会话引擎使用相同的配置，会话数据就会共享。 （另外，在serializers are an all-or-nothing prospect Dancer2，让您真正有使用两个单独的应用程序）

下面是我给的dancer-users mailing list的例子：

MyApp的/ lib目录/ MyApp.pm

package MyApp; 
use Dancer2; 

our $VERSION = '0.1'; 

get '/' => sub { 
    session foo => 'bar'; 
    template 'index'; 
}; 

true; 

MyApp的/ LIB/MyApp的/ API.pm

package MyApp::API; 
use Dancer2; 

set serializer => 'JSON'; 

get '/' => sub { 
    my $foo = session('foo') // 'fail'; 
    return { foo => $foo }; 
}; 

true; 

MyApp的/ bin中/ app.psgi

#!/usr/bin/env perl 

use strict; 
use warnings; 
use FindBin; 
use lib "$FindBin::Bin/../lib"; 

use MyApp; 
use MyApp::API; 
use Plack::Builder; 

builder { 
    mount '/' => MyApp->to_app; 
    mount '/api' => MyApp::API->to_app; 
}; 

如果您访问/路线，然后在同一浏览器的/api路线，你会得到

{"foo":"bar"} 

表明同一个会话两个请求都使用了变量。