查找两个文本文件的重复单词，使用命令行

Question

我有两个文本文件：

f1.txt 

boom Boom pow 
Lazy dog runs. 
The Grass is Green 
This is TEST 
Welcome 

和

f2.txt 

Welcome 
I am lazy 
Welcome, Green 
This is my room 
Welcome 
bye 

在Ubuntu的命令行我想：

awk 'BEGIN {RS=" "}FNR==NR {a[$1]=NR; next} $1 in a' f1.txt f2.txt 

和获得输出：

Green 
This 
is 

我所需的输出是：

lazy 
Green 
This is 
Welcome 

说明：我想比较两个txt文件，一行行。然后我想输出所有重复的单词。比赛应该不区分大小写。此外，逐行比较会更好，而不是在整个f2.txt文件中查找来自f1.txt的匹配。例如，如果它是在第6行而不是在f2.txt中的第5行，则“欢迎”这个词不应该在期望的输出中

Answer 1

那么。使用awk：

awk 'NR == FNR { for(i = 1; i <= NF; ++i) { a[NR,tolower($i)] = 1 }; next } { flag = 0; for(i = 1; i <= NF; ++i) { if(a[FNR,tolower($i)]) { printf("%s%s", flag ? OFS : "", $i); flag = 1 } } if(flag) print "" }' f1.txt f2.txt 

这种工作方式如下：

NR == FNR {         # While processing the first file: 
    for(i = 1; i <= NF; ++i) {    # Remember which fields were in 
    a[NR,tolower($i)] = 1     # each line (lower-cased) 
    } 
    next          # Do nothing else. 
} 
{           # After that (when processing the 
              # second file) 
    flag = 0         # reset flag so we know we haven't 
              # printed anything yet 
    for(i = 1; i <= NF; ++i) {    # wade through fields (words) 
    if(a[FNR,tolower($i)]) {    # if this field was in the 
              # corresponding line in the first 
              # file, then 
     printf("%s%s", flag ? OFS : "", $i) # print it (with a separator if it 
              # isn't the first) 
     flag = 1        # raise flag 
    } 
    } 
    if(flag) {        # and if we printed anything 
    print ""        # add a newline at the end. 
    } 
}