Excel进程不在VB.net中关闭

Question

我使用interop.excel创建了一个excel文件，并且进程未关闭。 这是我正在尝试使用的代码。

Private Sub converToExcel(fileLoc As String, ds As DataSet) 
    Dim xlApp As Excel.Application 
    Dim xlWorkBook As Excel.Workbook 
    Dim xlWorkBooks As Excel.Workbooks 
    Dim xlWorkSheet As Excel.Worksheet 
    Dim misValue As Object = System.Reflection.Missing.Value 
    Dim i As Integer 
    Dim j As Integer 

    xlApp = New Excel.Application 
    xlWorkBooks = xlApp.Workbooks 
    xlWorkBook = xlWorkBooks.Add(misValue) 
    xlWorkSheet = xlWorkBook.Sheets("sheet1") 

    For i = 0 To ds.Tables(0).Rows.Count - 1 
     For j = 0 To ds.Tables(0).Columns.Count - 1 
      xlWorkSheet.Columns.NumberFormat = "@" 
      xlWorkSheet.Cells(i + 1, j + 1) = String.Format("{0}", ds.Tables(0).Rows(i).Item(j).ToString()) 
     Next 
    Next 

    xlWorkSheet.SaveAs(fileLoc) 
    xlWorkBook.Close() 
    xlApp.Quit() 

    releaseObject(xlWorkSheet) 
    releaseObject(xlWorkBook) 
    releaseObject(xlWorkBooks) 
    releaseObject(xlApp) 

End Sub 
Private Sub releaseObject(ByVal obj As Object) 
    Try 
     System.Runtime.InteropServices.Marshal.ReleaseComObject(obj) 
     obj = Nothing 
    Catch ex As Exception 
     obj = Nothing 
    Finally 
     GC.Collect() 
    End Try 
End Sub 

我想我错过了一个COM对象，但似乎找不到解决方案。 此外，作为一个说明，这是在64位Windows 8上运行。 任何帮助将是伟大的！ 谢谢

Answer 1

尝试System.Runtime.InteropServices.Marshal.FinalReleaseComObject，这应该有所帮助...还应该调用xlWorkBook.Close（）和xlapp.quit，如果我记得正确。首先打电话给他们，然后将他们设置为无。

Answer 2

GC.Collect对于放置它的位置没有多大意义，如果有什么应该在从converToExcel返回后称之为。您也许需要等待终结者运行。就我个人而言，我认为Hans的答案是要走的路，但我从C＃编写office插件的个人经验知道，有时候需要做手工引用计数，特别是当您需要与旧版Office兼容时。 （有许多文档记录的问题，尤其是处理办公室事件时，只能通过手工引用计数才能可靠地解决。还有一些COM库在GC错误排序时根本不喜欢，但那不是这种情况与Office）

于是就在你的代码中的实际问题：有三个中间COM对象不在这里公布：

• xlWorkBook.Sheets返回类型的集合Excel.Sheets
• xlWorkSheet.Columns返回的COM对象类型Excel.Range
• xlWorkSheet.Cells也返回Excel.Range对象

除此之外，如果对Marshal.ReleaseComObject抛出你做错了什么在你手动引用计数异常，所以我不会在异常处理包裹。在进行手动引用计数时，每次跨越COM-> NET边界时都必须释放一次COM对象，这意味着需要在每次迭代循环中释放Excel.Range对象。

这里的代码，正常终止的Excel对我来说：

Imports Microsoft.Office.Interop 
Imports System.Runtime.InteropServices 

Private Sub converToExcel(fileLoc As String, ds As DataSet) 
    Dim xlApp As New Excel.Application 
    Dim xlWorkBooks As Excel.Workbooks = xlApp.Workbooks 
    Dim xlWorkBook As Excel.Workbook = xlWorkBooks.Add(System.Reflection.Missing.Value) 
    Dim xlWorkSheets As Excel.Sheets = xlWorkBook.Sheets 
    ' accessing the sheet by index because name is localized and your code will fail in non-english office versions 
    Dim xlWorkSheet As Excel.Worksheet = xlWorkSheets(1) 

    For i = 0 To ds.Tables(0).Rows.Count - 1 
     For j = 0 To ds.Tables(0).Columns.Count - 1 
      ' couldn't this be moved outside the loop? 
      Dim xlColumns As Excel.Range = xlWorkSheet.Columns 
      xlColumns.NumberFormat = "@" 
      Marshal.ReleaseComObject(xlColumns) 

      Dim xlCells As Excel.Range = xlWorkSheet.Cells 
      xlCells(i + 1, j + 1) = ds.Tables(0).Rows(i).Item(j).ToString() 
      Marshal.ReleaseComObject(xlCells) 
     Next 
    Next 

    xlWorkSheet.SaveAs(fileLoc) 
    'xlWorkBook.Close() -- not really necessary 
    xlApp.Quit() 

    Marshal.ReleaseComObject(xlWorkSheet) 
    Marshal.ReleaseComObject(xlWorkSheets) 
    Marshal.ReleaseComObject(xlWorkBook) 
    Marshal.ReleaseComObject(xlWorkBooks) 
    Marshal.ReleaseComObject(xlApp) 
End Sub 

如果要格外小心，你会想从办公室API处理异常和调用ReleaseComObject的最后子句中。定义一个通用包装并写入using-clause而不是try-finally会很有帮助（使包装不是一个类，所以你不会在堆上分配这些包装）。

Answer 3

像这样的手动内存管理从来没有工作。这是一个很久以前就知道的问题，也是垃圾收集者被发明的核心原因。程序员只是永远忘记释放内存。

当您正在使用的内存看不到时，它会变得非常困难。您的代码中肯定是这种情况，xlWorkSheet.Cells(i + 1, j + 1)表达式使用不少于三个引用。一个用于由Cells属性返回的范围对象，一个用于由i+1选择的子范围对象，另一个用于由j+1选择的子范围对象。 VB.NET语言提供的非常好的语法糖，没有它写COM代码是非常痛苦的。但没有帮助，让你看到参考。您不仅无法在源代码中看到它，调试器也无法帮助您查看它们。

在.NET中这是一个很好解决的问题，它有一个垃圾收集器，它可以看到的一切。最基本的问题是你不给它一个解决你的问题的机会。你犯的错误是你停止了。可能通过在最后一条语句上设置断点，然后查看任务管理器并看到Excel.exe仍在运行。是的，这很正常。垃圾收集不是即时。

调用GC.Collect（）应该使其立即生效，但在运行项目的Debug版本的特定情况下不起作用。局部变量的生命周期随后会扩展到方法的末尾，帮助您在Autos/Locals/Watch窗口中看到它们。换句话说，GC.Collect（）实际上并不收集接口引用的任何。更多关于this post的行为。

简单的解决方法是到不停止。继续做有用的事情，给垃圾收集器一个运行的理由。或者在程序完成后让程序终止，Excel在终结器线程最后一次运行时终止。这是有效的，因为具有引用的局部变量不在范围之内。

但是每个人都想要即时修复。你可以通过删除所有的releaseObject（）调用来获得它。而且做起来像这个：

converToExcel(path, dset) 
GC.Collect() 
GC.WaitForPendingFinalizers() 

或者换句话说，强制收集后返回的方法。局部变量不再处于范围内，因此它们无法保留到Excel引用。它现在也可以在你调试它的时候工作，就像你在没有调试器的情况下运行Release版本时一样。

Answer 4

Dim xlp() As Process = Process.GetProcessesByName("EXCEL") 

For Each Process As Process In xlp 
    Process.Kill() 
    If Process.GetProcessesByName("EXCEL").Count = 0 Then 
     Exit For 
    End If 
Next 

Answer 5

终于解决了:)

Private Function useSomeExcel(ByVal Excelfilename As String) 
    Dim objExcel As Excel.Application 
    Dim objWorkBook As Excel.Workbook 
    Dim objWorkSheets As Excel.Worksheet 

    Dim datestart As Date = Date.Now 
    objExcel = CreateObject("Excel.Application") 'This opens... 
    objWorkBook = objExcel.Workbooks.Open(Excelfilename) ' ... excel process 
    Dim dateEnd As Date = Date.Now 
    End_Excel_App(datestart, dateEnd) ' This closes excel proces 
End Function 

使用这种方法

Private Sub End_Excel_App(datestart As Date, dateEnd As Date) 
    Dim xlp() As Process = Process.GetProcessesByName("EXCEL") 
    For Each Process As Process In xlp 
    If Process.StartTime >= datestart And Process.StartTime <= dateEnd Then 
     Process.Kill() 
     Exit For 
    End If 
    Next 
    End Sub 

此方法关闭especific进程打开。

Answer 6

'Get the PID from the wHnd and kill the process. 
' open the spreadsheet 
ImportFileName = OpenFileDialog1.FileName 
excel = New Microsoft.Office.Interop.Excel.ApplicationClass 
wBook = excel.Workbooks.Open(ImportFileName) 
hWnd = excel.Hwnd 
Dim id As Integer = GetWindowThreadProcessId(hWnd, ExcelPID) 

---

Sub CloseExcelFile() 
     Try 
      ' first try this 
      wBook.Saved = True 
      wBook.Close() 
      excel.Quit() 

      ' then this. 
      System.Runtime.InteropServices.Marshal.ReleaseComObject(excel) 
      excel = Nothing 

      ' This appears to be the only way to close excel! 
      Dim oProcess As Process 
      oProcess = Process.GetProcessById(ExcelPID) 
      If oProcess IsNot Nothing Then 
       oProcess.Kill() 
      End If 

     Catch ex As Exception 
      excel = Nothing 
     Finally 
      GC.Collect() 
     End Try 
    End Sub