如何使用Inno Setup中的BASS库将音频静音（更改音量）

Question

Bass Audio Library on/off Button中的这段代码是否“暂停”，如何将其更改为“静音”？

我应该改变什么？

const 
    BASS_SAMPLE_LOOP = 4; 
    BASS_ACTIVE_STOPPED = 0; 
    BASS_ACTIVE_PLAYING = 1; 
    BASS_ACTIVE_STALLED = 2; 
    BASS_ACTIVE_PAUSED = 3; 
    BASS_UNICODE = $80000000; 
    BASS_CONFIG_GVOL_STREAM = 5; 
const 
    #ifndef UNICODE 
    EncodingFlag = 0; 
    #else 
    EncodingFlag = BASS_UNICODE; 
    #endif 
type 
    HSTREAM = DWORD; 

function BASS_Init(device: LongInt; freq, flags: DWORD; 
    win: HWND; clsid: Cardinal): BOOL; 
    external 'BASS_Init@files:bass.dll stdcall'; 
function BASS_StreamCreateFile(mem: BOOL; f: string; offset1: DWORD; 
    offset2: DWORD; length1: DWORD; length2: DWORD; flags: DWORD): HSTREAM; 
    external 'BASS_StreamCreateFile@files:bass.dll stdcall'; 
function BASS_Start: BOOL; 
    external 'BASS_Start@files:bass.dll stdcall'; 
function BASS_Pause: BOOL; 
    external 'BASS_Pause@files:bass.dll stdcall'; 
function BASS_ChannelPlay(handle: DWORD; restart: BOOL): BOOL; 
    external 'BASS_ChannelPlay@files:bass.dll stdcall'; 
function BASS_SetConfig(option: DWORD; value: DWORD): BOOL; 
    external 'BASS_SetConfig@files:bass.dll stdcall'; 
function BASS_ChannelIsActive(handle: DWORD): DWORD; 
    external 'BASS_ChannelIsActive@files:bass.dll stdcall'; 
function BASS_Free: BOOL; 
    external 'BASS_Free@files:bass.dll stdcall'; 

var 
    SoundStream: HSTREAM; 
    SoundCtrlButton: TNewButton; 

procedure SoundCtrlButtonClick(Sender: TObject); 
begin 
    case BASS_ChannelIsActive(SoundStream) of 
    BASS_ACTIVE_PLAYING: 
    begin 
     if BASS_Pause then 
     SoundCtrlButton.Caption := 
      ExpandConstant('{cm:SoundCtrlButtonCaptionSoundOn}'); 
    end; 
    BASS_ACTIVE_PAUSED: 
    begin 
     if BASS_Start then 
     SoundCtrlButton.Caption := 
      ExpandConstant('{cm:SoundCtrlButtonCaptionSoundOff}'); 
    end; 
    end; 
end; 

procedure InitializeWizard; 
begin 
    ExtractTemporaryFile('tune.mp3'); 
    if BASS_Init(-1, 44100, 0, 0, 0) then 
    begin 
    SoundStream := BASS_StreamCreateFile(False, 
     ExpandConstant('{tmp}\tune.mp3'), 0, 0, 0, 0, 
     EncodingFlag or BASS_SAMPLE_LOOP); 
    BASS_SetConfig(BASS_CONFIG_GVOL_STREAM, 2500); 
    BASS_ChannelPlay(SoundStream, False); 

    SoundCtrlButton := TNewButton.Create(WizardForm); 
    SoundCtrlButton.Parent := WizardForm; 
    SoundCtrlButton.Left := 8; 
    SoundCtrlButton.Top := WizardForm.ClientHeight - 
     SoundCtrlButton.Height - 8; 
    SoundCtrlButton.Width := 40; 
    SoundCtrlButton.Caption := 
     ExpandConstant('{cm:SoundCtrlButtonCaptionSoundOff}'); 
    SoundCtrlButton.OnClick := @SoundCtrlButtonClick; 
    end; 
end; 

procedure DeinitializeSetup; 
begin 
    BASS_Free; 
end; 

Answer 1

为了控制音量，则使用与BASS_SetConfigoption设置为：

• BASS_CONFIG_GVOL_STREAM为 “流”，例如创建使用BASS_StreamCreateFile;
• BASS_CONFIG_GVOL_MUSIC“音乐”，例如创建使用BASS_MusicLoad。

SoundCtrlButtonClick将取代您的问题中暂停/恢复执行相同命名的功能。

var 
    Muted: Boolean; 

procedure SoundCtrlButtonClick(Sender: TObject); 
begin 
    if not Muted then 
    begin 
    if BASS_SetConfig(BASS_CONFIG_GVOL_STREAM, 0) then 
    begin 
     SoundCtrlButton.Caption := 'unmute'; 
     Muted := True; 
    end; 
    end 
    else 
    begin 
    if BASS_SetConfig(BASS_CONFIG_GVOL_STREAM, 2500) then 
    begin 
     SoundCtrlButton.Caption := 'mute'; 
     Muted := False; 
    end; 
    end; 
end;