随机化节点顺序XSLT

Question

我有一个包含这样的节点的XML文件：

<values> 
    <item>item 1</item> 
    <item>item 2</item> 
    <item>item 3</item> 
    <item>item 4</item> 
    <item>item 5</item> 
</values> 

我想使用XSLT来获得一个随机化的顺序列表：

<values> 
    <item>item 3</item> 
    <item>item 5</item> 
    <item>item 1</item> 
    <item>item 4</item> 
    <item>item 2</item> 
</values> 

我无法使用外部资源，如 “xmlns：java =”java.lang.Math“ and ”xmlns：math =“http://exslt.org/math”

由于限制。

也许这链接可能帮助：

http://fxsl.sourceforge.net/articles/Random/Casting%20the%20Dice%20with%20FXSL-htm.htm

Answer 1

以下样式表写在随机顺序的项目，以输出树。样式表需要在运行时将外部“初始种子”编号作为参数提供。

注意：由于这些项目只是在不进行处理的情况下重新排序，因此无需对它们进行排序，并且EXSLT node-set（）函数毕竟不是必需的。

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"> 
<xsl:output method="xml" version="1.0" encoding="utf-8" indent="yes"/> 

<xsl:param name="initial-seed" select="123"/> 

<xsl:template match="/"> 
    <values> 
      <xsl:call-template name="pick-random-item"> 
       <xsl:with-param name="items" select="values/item"/> 
      </xsl:call-template> 
    </values> 
</xsl:template> 

<xsl:template name="pick-random-item"> 
    <xsl:param name="items" /> 
    <xsl:param name="seed" select="$initial-seed"/> 
    <xsl:if test="$items"> 
     <!-- generate a random number using the "linear congruential generator" algorithm --> 
     <xsl:variable name="a" select="1664525"/> 
     <xsl:variable name="c" select="1013904223"/> 
     <xsl:variable name="m" select="4294967296"/> 
     <xsl:variable name="random" select="($a * $seed + $c) mod $m"/> 
     <!-- scale random to integer 1..n --> 
     <xsl:variable name="i" select="floor($random div $m * count($items)) + 1"/> 
     <!-- write out the corresponding item --> 
     <xsl:copy-of select="$items[$i]"/> 
     <!-- recursive call with the remaining items --> 
     <xsl:call-template name="pick-random-item"> 
      <xsl:with-param name="items" select="$items[position()!=$i]"/> 
      <xsl:with-param name="seed" select="$random"/> 
     </xsl:call-template> 
    </xsl:if> 
</xsl:template> 

</xsl:stylesheet> 

应用到您的输入与所述默认的初始种子（123），则输出为：

<?xml version="1.0" encoding="utf-8"?> 
<values> 
    <item>item 2</item> 
    <item>item 3</item> 
    <item>item 1</item> 
    <item>item 4</item> 
    <item>item 5</item> 
</values> 

当与的1234种子进行时，输出为：

<?xml version="1.0" encoding="utf-8"?> 
<values> 
    <item>item 4</item> 
    <item>item 1</item> 
    <item>item 5</item> 
    <item>item 2</item> 
    <item>item 3</item> 
</values>