映射数组哈希与逻辑定义运算符

Question

我想设置默认值，如果用户不提供它

以下是我的代码。请指出如何将其与//运算符来完成

use Data::Dumper; 
use Getopt::Long; 
my @viewFiles = ("cdl", "lef", "verilog", "lib"); 
my %viewPaths; 
my $pctDir = "."; 
GetOptions(
    "pctDir=s" => \$pctDir, 
    "cdl=s" => \$viewPaths{"cdl"}, 
    "lef=s" => \$viewPaths{"lef"}, 
    "verilog=s" => \$viewPaths{"verilog"}, 
    "lib=s" => \$viewPaths{"lib"}, 
); 
@viewPaths{@viewFiles} //= ("$pctDir/cdl/topCellName.cdl", "$pctDir/lef/topCellName.lef", "$pctDir/model/verilog/topCellName.v", "$pctDir/model/timing/lib/topCellName.lib"); 
print Dumper \%viewPaths; 

输出为：

$VAR1 = { 
      'cdl' => undef, 
      'verilog' => undef, 
      'lib' => './model/timing/lib/topCellName.lib', 
      'lef' => undef 
     }; 

预期输出：

$VAR1 = { 
      'cdl' => './cdl/topCellName.cdl', 
      'verilog' => './model/verilog/topCellName.v', 
      'lib' => './model/timing/lib/topCellName.lib', 
      'lef' => './lef/topCellName.lef' 
     }; 

Answer 1

布尔运算符和//操作上标量，所以他们的LHS在标量上下文中进行评估。这意味着，

@viewPaths{@viewFiles} //= ...; 

相当于

$viewPaths{ $viewFiles[-1] } //= ...; 

因此，相反，你需要做的每个条目：

my @viewFiles = ("cdl", "lef", "verilog", "lib"); 
my %defaults; 
@defaults{@viewFiles} = ("pctDir/cdl/topCellName.cdl", "pctDir/lef/topCellName.lef", "pctDir/model/verilog/topCellName.v", "pctDir/model/timing/lib/topCellName.lib"); 

$viewPaths{$_} //= $defaults{$_} for keys %defaults; 

但是作为替代 - 预填充哈希应工作我认为：

#!/usr/bin/perl 
use warnings; 
use strict; 

use Data::Dumper; 
use Getopt::Long; 
my @viewFiles = ("cdl", "lef", "verilog", "lib"); 
my %viewPaths; 

@viewPaths{@viewFiles} = ("pctDir/cdl/topCellName.cdl", "pctDir/lef/topCellName.lef", "pctDir/model/verilog/topCellName.v", "pctDir/model/timing/lib/topCellName.lib"); 

GetOptions(
    "cdl=s" => \$viewPaths{"cdl"}, 
    "lef=s" => \$viewPaths{"lef"}, 
    "verilog=s" => \$viewPaths{"verilog"}, 
    "lib=s" => \$viewPaths{"lib"}, 
); 

print Dumper \%viewPaths;