需要帮助合并Excel VBA的两个宏

Question

这两个宏都是我在网上找到并且适合我使用的宏。我使用此代码，它的工作原理以及具体的数据分离到新的工作表：

 Sub Copy_To_Worksheets() 
'Note: This macro use the function LastRow 
    Dim My_Range As Range 
    Dim FieldNum As Long 
    Dim CalcMode As Long 
    Dim ViewMode As Long 
    Dim ws2 As Worksheet 
    Dim Lrow As Long 
    Dim cell As Range 
    Dim CCount As Long 
    Dim WSNew As Worksheet 
    Dim ErrNum As Long 

    'Set filter range on ActiveSheet: A1 is the top left cell of your filter range 
    'and the header of the first column, D is the last column in the filter range. 
    'You can also add the sheet name to the code like this : 
    'Worksheets("Sheet1").Range("A1:D" & LastRow(Worksheets("Sheet1"))) 
    'No need that the sheet is active then when you run the macro when you use this. 


    Set My_Range = Range("A1:Z" & Range("A" & Rows.Count).End(xlUp).Row) 
    My_Range.Parent.Select 

    If ActiveWorkbook.ProtectStructure = True Or _ 
     My_Range.Parent.ProtectContents = True Then 
     MsgBox "Sorry, not working when the workbook or worksheet is protected", _ 
       vbOKOnly, "Copy to new worksheet" 
     Exit Sub 
    End If 

    'This example filters on the first column in the range(change the field if needed) 
    'In this case the range starts in A so Field:=1 is column A, 2 = column B, ...... 
    FieldNum = 5 'I changed this to 3 for column C 

    'Turn off AutoFilter 
    My_Range.Parent.AutoFilterMode = False 

    'Change ScreenUpdating, Calculation, EnableEvents, .... 
    With Application 
     CalcMode = .Calculation 
     .Calculation = xlCalculationManual 
     .ScreenUpdating = False 
     .EnableEvents = False 
    End With 
    ViewMode = ActiveWindow.View 
    ActiveWindow.View = xlNormalView 
    ActiveSheet.DisplayPageBreaks = False 

    'Add a worksheet to copy the a unique list and add the CriteriaRange 
    Set ws2 = Worksheets.Add 

    With ws2 
     'first we copy the Unique data from the filter field to ws2 
     My_Range.Columns(FieldNum).AdvancedFilter _ 
       Action:=xlFilterCopy, _ 
       CopyToRange:=.Range("A1"), Unique:=True 

     'loop through the unique list in ws2 and filter/copy to a new sheet 
     Lrow = .Cells(Rows.Count, "A").End(xlUp).Row 
     For Each cell In .Range("A2:A" & Lrow) 

      'Filter the range 
      My_Range.AutoFilter Field:=FieldNum, Criteria1:="=" & _ 
      Replace(Replace(Replace(cell.Value, "~", "~~"), "*", "~*"), "?", "~?") 

      'Check if there are no more then 8192 areas(limit of areas) 
      CCount = 0 
      On Error Resume Next 
      CCount = My_Range.Columns(1).SpecialCells(xlCellTypeVisible) _ 
        .Areas(1).Cells.Count 
      On Error GoTo 0 
      If CCount = 0 Then 
       MsgBox "There are more than 8192 areas for the value : " & cell.Value _ 
        & vbNewLine & "It is not possible to copy the visible data." _ 
        & vbNewLine & "Tip: Sort your data before you use this macro.", _ 
         vbOKOnly, "Split in worksheets" 
      Else 
       'Add a new worksheet 
       Set WSNew = Worksheets.Add(After:=Sheets(Sheets.Count)) 
       On Error Resume Next 
       WSNew.Name = cell.Value 
       If Err.Number > 0 Then 
        ErrNum = ErrNum + 1 
        WSNew.Name = "Error_" & Format(ErrNum, "0000") 
        Err.Clear 
       End If 
       On Error GoTo 0 

       'Copy the visible data to the new worksheet 
       My_Range.SpecialCells(xlCellTypeVisible).Copy 
       With WSNew.Range("A1") 
        ' Paste:=8 will copy the columnwidth in Excel 2000 and higher 
        ' Remove this line if you use Excel 97 
        .PasteSpecial Paste:=8 
        .PasteSpecial xlPasteValues 
        .PasteSpecial xlPasteFormats 
        Application.CutCopyMode = False 
        .Select 
       End With 
      End If 

      'Show all data in the range 
      My_Range.AutoFilter Field:=FieldNum 

     Next cell 

     'Delete the ws2 sheet 
     On Error Resume Next 
     Application.DisplayAlerts = False 
     .Delete 
     Application.DisplayAlerts = True 
     On Error GoTo 0 

    End With 

    'Turn off AutoFilter 
    My_Range.Parent.AutoFilterMode = False 

    If ErrNum > 0 Then 
     MsgBox "Rename every WorkSheet name that start with ""Error_"" manually" _ 
      & vbNewLine & "There are characters in the name that are not allowed" _ 
      & vbNewLine & "in a sheet name or the worksheet already exist." 
    End If 

    'Restore ScreenUpdating, Calculation, EnableEvents, .... 
    My_Range.Parent.Select 
    ActiveWindow.View = ViewMode 
    With Application 
     .ScreenUpdating = True 
     .EnableEvents = True 
     .Calculation = CalcMode 
    End With 
    End Sub 

我需要什么是一组特定的公式添加到从上面的宏创建的每个表的下方，帮助。下面的宏将公式添加到工作簿中的所有工作表。我需要它将公式添加到仅在上面的宏中创建的工作表。根据源数据的不同，每次生成的图纸数量都会发生更改。我认为最好将底部的宏合并到顶端，但我不知道如何去做。

Sub Insert_Formulas() 
    Dim ws As Worksheet 

    For Each ws In ThisWorkbook.Worksheets 
    ws.Activate 

    'Start 
    NxtRw = Cells(Rows.Count, "B").End(xlUp).Row + 1 
    With Cells(NxtRw, "B") 
    .Value = "Total Open Cases" 
    End With 

    With Cells(NxtRw, "C") 
     .EntireRow.Insert 
     .Value = "Total Closed Cases" 
    End With 

    'Next Row below 
    NxtRw = Cells(Rows.Count, "B").End(xlUp).Row + 1 
    With Cells(NxtRw, "B") 
    .Formula = "=CountIf(B2:B" & NxtRw - 1 & ", ""Open*"")" 
    End With 

    With Cells(NxtRw, "C") 
    .Formula = "=CountIf(B2:B" & NxtRw - 1 & ", ""Closed*"")" 
    End With 
    Next 
End Sub 

任何帮助将不胜感激。

谢谢CK

Answer 1

如果参数化的功能，因此，它需要它需要的公式作为参数

Sub Insert_Formulas_Into_WorkSheet(ws As Worksheet) 

    ws.Activate 

    'Start 
    NxtRw = Cells(Rows.Count, "B").End(xlUp).Row + 1 
    With Cells(NxtRw, "B") 
    .Value = "Total Open Cases" 
    End With 

    With Cells(NxtRw, "C") 
     .EntireRow.Insert 
     .Value = "Total Closed Cases" 
    End With 

    'Next Row below 
    NxtRw = Cells(Rows.Count, "B").End(xlUp).Row + 1 
    With Cells(NxtRw, "B") 
    .Formula = "=CountIf(B2:B" & NxtRw - 1 & ", ""Open*"")" 
    End With 

    With Cells(NxtRw, "C") 
    .Formula = "=CountIf(B2:B" & NxtRw - 1 & ", ""Closed*"")" 
    End With 
End Sub 

则每个新创建的工作表后，您可以添加公式中的工作表通过调用

Insert_Formulas_Into_WorkSheet WSNew 

Answer 2

我不会结合2个宏，只需调用从Copy_To_Worksheets宏Insert_Formulas宏在需要时。

要调用宏所有你需要的是这一行：

Insert_Formulas 

编辑回应评论：

鉴于你不知道有多少张被添加我有一个建议你可以试试。

高级别，将文本添加到每个工作表中的单元格以指示它是否是新建的。当新工作表创建时，单元应该说“新”。不新时，应该说“现有”。然后在

如果你想尝试一下，并让我知道什么是行不通的，我可以检查并帮助更新代码。

1. 在Copy_To_Worksheets宏观你需要添加一行来设置所有现有表“现有”
2. 在随后Copy_To_Worksheets宏添加一条线，使新的床单被置为“新”
3. 在Insert_Formulas宏中，仍循环遍历所有工作表，但检查工作表是否为“新建”，如果是，请运行代码以添加公式。

更清洁（但稍微困难）的选择是在每张纸上定义一个名称（每个纸张使用相同的名称并将范围限制在每​​张纸上），并使用该名称代替每张纸上的单元格。