将简单的Flash AS2代码转换为AS3

Question

我是Flash初学者，并遵循教程：http://www.webwasp.co.uk/tutorials/018/tutorial.php ...了解如何进行“实时绘制/绘制”效果。我没有意识到，如果我在AS2中创建了一些东西，我将无法将它嵌入（并使其工作）到我的根AS3文件中，在那里我还有其他一些东西在进行。我已经尝试了如何将AS2代码更改为AS3的提示，但它不起作用。我知道这是简单的代码，并且那里有一些天才可以弄清楚，但我很茫然。请帮忙！

这里的AS2代码：

_root.createEmptyMovieClip("myLine", 0); 

_root.onMouseDown = function() { 
    myLine.moveTo(_xmouse, _ymouse); 
    ranWidth = Math.round((Math.random() * 10)+2); 
    myLine.lineStyle(ranWidth, 0xff0000, 100); 
    _root.onMouseMove = function() { 
     myLine.lineTo(_xmouse, _ymouse); 
    } 
} 

_root.onMouseUp = function() { 
    _root.onMouseMove = noLine; 
} 

Answer 1

这里是AS3

import flash.display.Sprite; 
import flash.events.MouseEvent; 

var ranWidth:Number; 

//creation of a new clip (Sprite is the base class of MovieClip, 
//it's the same without the unneeded timeline) 
var myLine:Sprite = new Sprite(); 
addChild(myLine); 

//in AS3 the main container is stage, not _root 
//you see here the main difference between beginner AS3 and beginner AS2: 
//event listeners 
stage.addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown); 


function onMouseDown(event:MouseEvent):void 
{ 
    myLine.graphics.moveTo(mouseX, mouseY); 
    ranWidth = Math.round((Math.random() * 10)+2); 
    myLine.graphics.lineStyle(ranWidth, 0xff0000, 100); 
    stage.addEventListener(MouseEvent.MOUSE_MOVE, onMouseMove); 
    stage.addEventListener(MouseEvent.MOUSE_UP, onMouseUp); 
} 

//nesting function in other functions is not a good practice 
function onMouseMove(event:MouseEvent):void 
{ 
    myLine.graphics.lineTo(mouseX, mouseY); 
} 

function onMouseUp(event:MouseEvent):void 
{ 
    stage.removeEventListener(MouseEvent.MOUSE_MOVE, onMouseMove); 
    stage.removeEventListener(MouseEvent.MOUSE_UP, onMouseUp); 
}