11
我需要确定何时进程ID(PID)是32位或64位应用程序使用delphi,我该怎么做?我真的检查了IsWow64Process
函数,但使用了一个进程句柄而不是PID。如何确定进程ID(PID)是32位还是64位应用程序?
我需要确定何时进程ID(PID)是32位或64位应用程序使用delphi,我该怎么做?我真的检查了IsWow64Process
函数,但使用了一个进程句柄而不是PID。如何确定进程ID(PID)是32位还是64位应用程序?
您可以使用OpenProcess
函数来获取pid句柄,然后调用IsWow64Process
函数。
请记住,您必须使用GetProcAddress
函数加载IsWow64Process
函数,因为某些版本的Windows不包含此函数。
入住此示例代码
{$APPTYPE CONSOLE}
uses
Windows,
SysUtils;
type
TIsWow64Process = function(Handle:THandle; var IsWow64 : BOOL) : BOOL; stdcall;
var
IsWow64Process : TIsWow64Process;
procedure Init_IsWow64Process;
var
hKernel32 : Integer;
begin
hKernel32 := LoadLibrary(kernel32);
if (hKernel32 = 0) then RaiseLastOSError;
try
IsWow64Process := GetProcAddress(hkernel32, 'IsWow64Process');
finally
FreeLibrary(hKernel32);
end;
end;
function PidIs64BitsProcess(dwProcessId: DWORD): Boolean;
var
IsWow64 : BOOL;
PidHandle : THandle;
begin
Result := False;
if Assigned(IsWow64Process) then
begin
//check if the current app is running under WOW
if IsWow64Process(GetCurrentProcess(), IsWow64) then
Result := IsWow64
else
RaiseLastOSError;
//the current delphi App is not running under wow64, so the current Window OS is 32 bit
//and obviously all the apps are 32 bits.
if not Result then Exit;
PidHandle := OpenProcess(PROCESS_QUERY_INFORMATION,False,dwProcessId);
if PidHandle > 0 then
try
if (IsWow64Process(PidHandle, IsWow64)) then
Result := not IsWow64
else
RaiseLastOSError;
finally
CloseHandle(PidHandle);
end;
end;
end;
begin
try
Init_IsWow64Process;
//here pass the pid which you want to check
Writeln(BoolToStr(PidIs64BitsProcess(1940),True));
except
on E:Exception do
Writeln(E.Classname, ': ', E.Message);
end;
Readln;
end.
但是,如果这个代码在64位的Delphi编译的,这是不正确的结果。 “IsWow64Process中的IsWow64:如果该进程是在64位Windows下运行的64位应用程序,则该值也设置为FALSE。”我们总是从64位进程中获得False – 2015-11-25 11:20:24