如何在不知道列名的情况下获取列值？ SQL Server的

Question

我有表名作为@Table_Name

我列值@Value，但没有列名（但存在于第一的位置，并且可以Seek_id或prov_id ......我要比较我的价值与此ID）

我怎样才能比较该表的列名称值？

我想是这样

SELECT * FROM @Table_Name 
WHERE Table.Column[1].Value = @Value 

例如@Table_Name = bb_match和@Value = 6

Answer 1

这可能是有益的你 -

查询：

IF OBJECT_ID (N'dbo.bb_match') IS NOT NULL 
    DROP TABLE dbo.bb_match 

CREATE TABLE dbo.bb_match (seek_id INT, prov_id INT) 

INSERT INTO dbo.bb_match (seek_id, prov_id) 
VALUES (6, 1), (2, 6) 

DECLARE 
     @ColumnID TINYINT 
    , @Value INT 
    , @TableName SYSNAME 
    , @SQL NVARCHAR(500) 

SELECT 
     @ColumnID = 1 
    , @Value = 6 
    , @TableName = 'dbo.bb_match' 

SELECT @SQL = 'SELECT * FROM ' + @TableName + ' WHERE [' + c.name + '] = ' + CAST(@Value AS NVARCHAR(MAX)) 
FROM sys.objects o WITH (NOWAIT) 
JOIN sys.schemas s WITH (NOWAIT) ON o.[schema_id] = s.[schema_id] 
JOIN sys.columns c WITH (NOWAIT) ON o.[object_id] = c.[object_id] 
WHERE o.[type] = 'U' -- <-- only for tables columns 
    AND s.name + '.' + o.name = @TableName 
    AND c.column_id = @ColumnID 

PRINT @SQL 

EXEC sp_executesql @SQL 

短，但不安全（SYS.COLUMNS包含列名的表，视图，存储过程，...）：

SELECT @SQL = 'SELECT * FROM ' + @TableName + ' WHERE [' + c.name + '] = ' + CAST(@Value AS NVARCHAR(MAX)) 
FROM sys.columns c WITH (NOWAIT) 
WHERE c.[object_id] = OBJECT_ID(@TableName) 
    AND c.column_id = @ColumnID 

EXEC sys.sp_executesql @SQL

输出：

SELECT * FROM dbo.bb_match WHERE [seek_id] = 6 

结果：

seek_id  prov_id 
----------- ----------- 
6   1 

Answer 2

declare @sql varchar(MAX) 
declare @tablename varchar(100) = 'MyTable' --add your table name here 
declare @value varchar(100) = 'SomeValue' -- add your desired value hree 

select @sql = 'SELECT * FROM ' + @tablename + ' WHERE ' 
+ name 
+ ' = ''' + @value + '''' 
from sys.columns where object_id = object_id(@tablename) and column_id = 1 

exec (@sql) 

这有三个部分。首先我要宣布三个字符串。 @sql是我将建立查询的地方，@tablename和@value是查找/查找的表和搜索值。我已经输入了虚拟值MyTable和SomeValue来显示我在说什么

接下来我构建了sql语句。第一行设置的字符串作为SELECT * FROM MyTable WHERE

我然后在列名通过从SQL Server系统表sys.columns选择名称，过滤在所述第一柱（column_id = 1）和表名添加

下一步是在列中添加我们想要搜索的值。

最后，EXEC(@sql)将字符串解释为命令并运行它。