用于adobe air应用程序的cakephp用户身份验证

Question

我有一个使用flex和cakephp开发的Web应用程序。我的客户需要使用Adobe Air制作该Web应用程序的桌面应用程序。 Flex向Air的转换已成功完成。柔性应用程序flex和cakephp的通信是使用远程控制器处理的。

在空气应用程序中，我有一个使用cakephp默认用户身份验证来验证用户的问题。任何人都可以帮助我找到解决方案吗？

Answer 1

我建议你通过POST将你的用户凭证发送到你的cakephp后端。

在UsersController的登录功能将是这个样子：

public function login() { 
    if ($this->Auth->login()) { 
    $this->serviceResponse(Status::SUCCESS); 
} else { 
    $this->serviceResponse(Status::AUTH_FAILED); 
    } 
} 

// this is just an example out of my appcontroller to send json responses 
public function serviceResponse($code, $data = array()) { 
    $response = compact('code', 'data'); 
    $this->response->body(json_encode($response)); 
    $this->response->send(); 
    $this->shutdownProcess(); 
    exit; 
} 

// I also defined a class for return statuses 
class Status { 
    const SUCCESS = 'success'; 
    const ERROR = 'error'; 
    ... 
} 

Answer 2

基本上，你要发送的验证请求作为一个Ajax请求。要做到这一点，你需要修改标题，通过cookie捕获会话ID并发布它们以保持会话的活跃。它期望从Cake返回一个JSON对象。

我创建了几个Flex类，为Flex移动应用程序和CakePHP后端实现了这一点。它应该符合您的需求。

它有两个文件，AutoValidationUrlRequest.as扩展了HeaderURLRequest.as文件。我并不积极，但可能会有一些变数需要改变，但总的来说，它的运行效果非常好，并且可能不会花费更多的修改来让它在您的应用上运行。

要使用它，只需创建一个新的AutoValidationUrlRequest对象，并在headerUrlRequestComplete事件上添加事件侦听器，然后运行AutoValidationUrlRequest.send（...）以POST。还有一个方便的方法称为convertToPostVars，以方便Cake友好Post变量。

AutoValidationUrlRequest.as：

package libs 
{ 

import flash.events.Event; 
import flash.events.EventDispatcher; 
import flash.events.HTTPStatusEvent; 

import models.LocalDeviceData; 
import models.Model; 

import mx.collections.ArrayCollection; 
import mx.core.FlexGlobals; 
import mx.utils.ObjectUtil; 

[Event("LoginFailed")] 
[Event("MobileUserDoesNotExist")] 

public class AutoValidationURLRequest extends HeaderURLRequest 
{  
    public static const LOGIN_FAILED:String = "LoginFailed"; 
    public static const MOBILE_USER_DOES_NOT_EXIST:String = "MobileUserDoesNotExist"; 
    /** 
    * will automatically be set by this class, if not set will login 
    */ 
    public var requestHeaders:Object = new Object(); 
    private var _cookie:Object; 

    /** 
    * should be an object with name of the cookie variables parsed in as key/value pairs 
    */ 
    protected function set cookie(ck:Object):void{ 
     _cookie = ck; 
    } 

    protected function get cookie():Object{ 
     return _cookie; 
    } 

    public function AutoValidationURLRequest(){ 

    }; 

    public function send(url:String, postData:Object, generateUrlVars:Boolean = true):void{ 
     if(generateUrlVars){ 
      postData = convertToPostVars(postData); 
     } 
     sendRequest("http://yourwebsite.com"+url, postData, requestHeaders); 
    } 

    override protected function parseHeaders(e:HTTPStatusEvent):void{ 
     super.parseHeaders(e); 
     if('Set-Cookie' in headers){ 
      requestHeaders['Cookie'] = parseCookie(headers['Set-Cookie']); 
      //requestHeaders['User-Agent'] = headers['User-Agent']; 
     } 
    } 


    /** 
    * returns the cookie key/val string for send requests back to the server 
    */ 
    protected function parseCookie(cookieString:String):String{ 
     var cookieObj:Object = new Object(); 
     var cookieBits:Array = cookieString.split("; "); 
     return cookieBits[0]; 

     /* 
     for each(var ck:String in cookieBits){ 
      var cb:Array = ck.split("="); 
      cookieObj[cb[0]] = cb[1]; 
     } 
     return cookieObj; 
     */ 
    } 

} 
} 

HeaderURLRequest.as：

package libs 
{ 

import flash.events.Event; 
import flash.events.EventDispatcher; 
import flash.events.HTTPStatusEvent; 
import flash.net.URLLoader; 
import flash.net.URLRequest; 
import flash.net.URLRequestHeader; 
import flash.net.URLRequestMethod; 
import flash.net.URLVariables; 

import mx.core.FlexGlobals; 
import mx.rpc.events.ResultEvent; 
import mx.utils.ObjectUtil; 


[Event("headerUrlRequestComplete")] 

public class HeaderURLRequest extends EventDispatcher 
{ 
    public static const HEADERURLREQUEST_COMPLETE:String = "headerUrlRequestComplete"; 

    public var headers:Array = []; 
    public var data:Object = new Object(); 
    public var variables:Object = new Object(); 
    public var invalidFields:Object = new Object(); 
    public var errorMsg:String = ""; 


    /** 
    * the headers array must contain an object with a 'name' key and a 'value' key eg: cookie: <cookieStr> 
    */ 
    public function HeaderURLRequest():void{ 
    } 

    public function sendRequest(url:String, postData:Object = null, requestHeaders:Object = null):void{ 
     var urlLoader:URLLoader = new URLLoader() 
     var urlRequest : URLRequest = new URLRequest(url); 

     //make it an ajax request 
     urlRequest.requestHeaders.push(new URLRequestHeader('X-Requested-With', 'XMLHttpRequest')); 

     for(var header:* in requestHeaders){ 
      var authHeader:URLRequestHeader = new URLRequestHeader(header as String, requestHeaders[header]); 
      urlRequest.requestHeaders.push(authHeader) 
     } 
     var urlVariables:URLVariables = new URLVariables(); 
     for (var vars:* in postData){ 
      urlVariables[vars] = postData[vars]; 
     } 

     urlRequest.method = URLRequestMethod.POST 
     urlRequest.data = urlVariables; 
     urlLoader.addEventListener(Event.COMPLETE, getData); 
     urlLoader.addEventListener(HTTPStatusEvent.HTTP_RESPONSE_STATUS, parseHeaders); 
     urlLoader.load(urlRequest); 

    } 

    public function convertToPostVars(postData:Object, prependKeyName:String = ""):Object{ 
     var params:Object = {}; 
     if(prependKeyName == ""){ 
      params['_method'] = 'POST'; 
     } 
     for (var item:* in postData){ 
      var objtype:Object = ObjectUtil.getClassInfo(postData[item]); 
      if(objtype.name == "Object"){ 
       var modelKeyName:String = prependKeyName+"["+item+"]"; 
       var subParams:Object = convertToPostVars(postData[item],modelKeyName); 
       params = merge(params, subParams); 
      }else{ 
       params["data"+prependKeyName+"["+item+"]"] = postData[item]; 
      } 
     } 
     return params; 
    } 

    public function flashErrorMsg():String{ 
     var err:String = errorMsg; 
     errorMsg = ""; 
     return err; 
    } 

    protected function parseHeaders(e:HTTPStatusEvent):void{ 
     var i:Number=0; 
     headers = []; 
     for each(var header:URLRequestHeader in e.responseHeaders){ 
      headers[header.name] = header.value; 
     i++; 
     } 
    } 

    protected function getData(e:Event):void{ 
     //trace('data: '); 
     if(e.currentTarget.data == ''){ 
      e.currentTarget.data = '{}'; 
     } 
     data = JSON.parse(e.currentTarget.data); 

     //trace(ObjectUtil.toString(data)); 
     if(data.hasOwnProperty('variables')){ 
      variables = data.variables; 
      if (variables != null){ 
       if(variables.hasOwnProperty('invalidFields')){ 
        invalidFields = variables.invalidFields; 
        for (var error:String in invalidFields){ 
         errorMsg += invalidFields[error] + "\n\n"; 
        } 
       } 
      }else{ 
       //no variable data found!! 
      } 
     } 
     dispatchEvent(new Event(HEADERURLREQUEST_COMPLETE)); 
    } 

    public function isEmpty(obj:Object){ 
     var isEmpty:Boolean = true; 
     for (var n in obj) { isEmpty = false; break; } 
     return isEmpty; 
    } 

    public function merge(obj0:Object, obj1:Object):Object 
    { 
     var obj:Object = { }; 
     for(var p:String in obj0) 
     { 
      obj[ p ] = (obj1[ p ] != null) ? obj1[ p ] : obj0[ p ]; 
      //trace(p, ' : obj0', obj0[ p ], 'obj1', obj1[ p ], '-> new value = ', obj[ p ]); 
     } 
     for (var p1:String in obj1){ 
      if(!obj.hasOwnProperty(p1)){ 
       obj[ p1 ] = obj1[ p1 ] ; 
      } 
     } 
     return obj; 
    } 
} 
} 

而且，利用此与我forked version of Jose Gonzalez's CakePHP ajax_controller plugin是非常方便的。它基本上接受任何Ajax请求并转换所有视图变量并将它们输出到JSON对象中，而不是渲染视图。否则，如果您没有使用ajax请求，Cake将正常呈现视图。祝你好运！