阅读字符串输入

Question

我试图写读类的实例来读取输入的字符串如下：

"1 3 -  
- 2 3  
- - 5" 

转换成[[Maybe Int]]

“ - ”将被翻译成Nothing “ 3" 将是Just 3

"('a',3) - ('b',7) 
('c',5) ('e',0) - 
('d',9) - ('h',8)" 

转换成[[Maybe (Char,Int)]]

“ - ”将被翻译成没什么 “（‘A’，3）”将Just ('a',3)

我试图用字符的处理列表给他们写，但它需要大量的工作。你有什么建议吗？对不起，我对Haskell很新，所以我问你这个问题。 :(

Answer 1

如果你摆脱了-条目，你可以很快做到这一点作为

Prelude> (map (map read) . map words. lines $ "('a',3) ('b',4)\n('c',5)")::[[(Char,Int)]] 
[[('a',3),('b',4)],[('c',5)]] 

或者将其定义为功能

genericReadLines :: Read a => String -> [[a]] 
genericReadLines = map (map read) . map words. lines 

，你可以这样使用：

*Main> (genericReadLines "('a',3) ('b',4)\n('c',5)")::[[(Char,Int)]] 
[[('a',3),('b',4)],[('c',5)]] 

但你可能会发现它更容易做

readCharInts :: String -> [[(Char,Int)]] 
readCharInts = genericReadLines 

readInts :: String -> [[Int]] 
readInts = genericReadLines 

所以，你可以只输入

*Main> readInts "1 2 3\n4 5 6\n7 8 9" 
[[1,2,3],[4,5,6],[7,8,9]] 
*Main> readCharInts "('a',3) ('b',4)\n('c',5)" 
[[('a',3),('b',4)],[('c',5)]] 

---

但是关于保持-什么？您必须使用Maybe数据类型来表示对列表中的某些点没有值;我们可以使用-作为Nothing和a的简写，作为Just a的简写。

read' :: Read a => String -> Maybe a 
read' "-" = Nothing 
read' xs = Just (read xs) 

我要提醒你，代码是脆弱的，如果你的数据也可能会被'-'，但也许它不能。

genericMaybeReadLines :: Read a => String -> [[Maybe a]] 
genericMaybeReadLines = map (map read') . map words. lines 

然后我们就可以有

readMaybeCharInts :: String -> [[Maybe (Char,Int)]] 
readMaybeCharInts = genericMaybeReadLines 

readMaybeInts :: String -> [[Maybe Int]] 
readMaybeInts = genericMaybeReadLines 

所以现在我们能做的

*Main> readMaybeCharInts "('a',3) ('b',4)\n- ('c',5)" 
[[Just ('a',3),Just ('b',4)],[Nothing,Just ('c',5)]] 
*Main> readMaybeInts "2 3 -\n4 - 2" 
[[Just 2,Just 3,Nothing],[Just 4,Nothing,Just 2]]