触发器在Oracle中：没有找到数据

Question

请检查我的代码，我很少用触发器与AFTER子句，非常感谢：

set serveroutput on; 
create or replace trigger tvideo_2 after insert on video for each row 
declare 
pragma autonomous_transaction; 
v_title video.title%type; /* Declare a variable to check title that contain '18+' */ 
begin 
select title into v_title from video where video.videoid=:new.videoid; 
if v_title like '%18+%' then 
update video 
set age=18 
where videoid=:new.videoid; 
dbms_output.put_line('Video '||:new.videoid||' has been updated age to 18+'); 
else 
dbms_output.put_line('Video '||:new.videoid||' is not 18+!'); 
end if; 
end; 
/
insert into video values('V5', '18+', 240, 19); 
VIDEO properties: (videoid, title, duration, age) 

Answer 1

使用pragma autonomous_transaction意味着触发无法看到刚刚插入的行和导致它被解雇。

当你删除主键并且预先插入了一个具有相同ID的记录时，它的即行将被你的触发器更新，而不是你插入的新行 - 所以它仍然不会做什么你想要的，重复PK值是不明智的。

如果必须将其作为after insert触发器执行此操作，则可以删除for each row，这样可以避免大概试图避免的突变表问题，但是必须查询整个表才能找到要更新的行：

create or replace trigger tvideo_2 after insert on video 
begin 
    update video 
    set age = 18 
    where title like '%18+%' 
    and age != 18; 
end; 
/

或者，如果你想打印一个消息：

create or replace trigger tvideo_2 after insert on video 
begin 
    for rec in (
    select videoid, title 
    from video 
    where title like '%18+%' 
    and age != 18 
) 
    loop 
    update video 
    set age = 18 
    where video.videoid = rec.videoid; 
    dbms_output.put_line('Video '||rec.videoid||' has been updated age to 18+'); 
    end loop; 
end; 
/

但在任何存储的PL/SQL中使用触发器dbms_output，还是真的，是不是一个好主意 - 如果客户端会话那插入没有'不看消息的输出缓冲区，而且很可能没有任何东西可以看到它。

你也可以使用明确的游标for update然后update .. where current of。

无论采用哪种方式，您都必须查询整个表格，这并不是非常高效 - 每次插入新表格时都会检查所有现有行，而不是仅仅检查单个新值。一个触发器并不适合做那么多工作 - 即使它只是实际更新一行（或没有！），它必须每插入查询所有内容（）。这不会很好地扩展。

还有其他方法可以避免突变表问题，但任何事情都将成为黑客攻击。明智的方式做，这是一个之前，插入行级触发器：

create or replace trigger tvideo_2 before insert on video for each row 
begin 
    if :new.title like '%18+%' then 
    :new.age := 18; 
    dbms_output.put_line('Video '||:new.videoid||' has been updated age to 18+'); 
    else 
    dbms_output.put_line('Video '||:new.videoid||' is not 18+!'); 
    end if; 
end; 
/

（约使用dbms_output相同的警告），但是，这似乎是禁止的某些原因。