通过VBA将除Excel以外的所有excel表导出为CSV格式？

Question

基于我在这里找到的其他一些东西，我做了以下脚本来完成我想要的东西。它会将excel文件中除4个特定页面外的所有页面导出为CSV文件，并将日期附加到它们，并将它们保存到日期文件夹中。唯一的问题是它重命名它在原始处理文件中导出的工作表。我该如何纠正这一点？

Sub SaveLCPWorksheetsAsCsv() 

Dim WS As Excel.Worksheet 
Dim SaveToDirectory As String 

Dim CurrentWorkbook As String 
Dim CurrentFormat As Long 

CurrentWorkbook = ThisWorkbook.FullName 
CurrentFormat = ThisWorkbook.FileFormat 
' Store current details for the workbook 

    SaveToDirectory = "C:\test\" & Format(Date - 1, "YYYYMM") & "\" 

    If Len(Dir(SaveToDirectory, vbDirectory)) = 0 Then 
    MkDir SaveToDirectory 
    End If 

    For Each WS In ThisWorkbook.Worksheets 
    If WS.Name <> "Input" And WS.Name <> "Ref" And WS.Name <> "Total" And WS.Name <> "Affected Accounts" Then 
     WS.SaveAs SaveToDirectory & WS.Name & "_" & Format(Date - 1, "YYYYMMDD"), xlCSV 
    End If 
    Next 

Application.DisplayAlerts = False 
    ThisWorkbook.SaveAs Filename:=CurrentWorkbook, FileFormat:=CurrentFormat 
Application.DisplayAlerts = True 
' Temporarily turn alerts off to prevent the user being prompted 
' about overwriting the original file. 

End Sub 

Answer 1

Sub Tester() 

Dim ws As Worksheet, wb As Workbook 

    For Each ws In ThisWorkbook.Worksheets 
     ws.Copy 'creates a new workbook 
     With ActiveWorkbook 
      .SaveAs "C:\temp\" & ws.Name & "_blah.csv", xlCSV 
      .Close False 
     End With 
    Next ws 

End Sub