SAS：重命名宏目录

Question

我想将宏存储在目录中。这样做可以让许多宏只与一个文件共享，并且引入了与用户分离的程度。

来存储我的宏，我运行一个程序，如

/* HelloWorld.sas */ 
libname pwd ".";    /* assign current directory */ 
option mstored sasmstore=pwd; /* set pwd as storage directory */ 

%macro HelloWorld() 
    /store source;   /* store compiled macro along with its source */ 
    data _null_; 
    put "Hello, World!"; 
    run; 
%mend; 

这在目录中创建一个sasmacr.sas7bcat文件，在其中HelloWorld.sas生活。然后我可以在文件移动到另一个目录，如C:\myMacros和运行下面的程序：

/* CallHelloWorld.sas */ 
libname myMacros 'C:\myMacros'; 
option mstored sasmstore=myMacros; 

%HelloWorld(); 

宏HelloWorld()被称为没有错误。但是，如果我想将HelloWorld()宏作为“HelloWorld”宏套件的一部分，我不能简单地将Windows资源管理器中的目录名称从sasmacr.sas7bcat更改为HelloWorld.sas7bcat。当我这样做并尝试再次运行CallHelloWorld.sas（关闭并重新打开SAS后），宏未解析。

1 /* CallHelloWorld.sas */ 
2 libname myMacros 'C:\myMacros'; 
NOTE: Libref MYMACROS was successfully assigned as follows: 
     Engine:  V9 
     Physical Name: C:\myMacros 
3 option mstored sasmstore=myMacros; 
4 
5 %HelloWorld(); 
    - 
    180 
NOTE: The SAS System was unable to open the macro library referenced by the SASMSTORE = libref 
     MYMACROS. 
WARNING: Apparent invocation of macro HELLOWORLD not resolved. 

ERROR 180-322: Statement is not valid or it is used out of proper order. 

ERROR: Catalog MYMACROS.SASMACR does not exist. 
NOTE: The SAS System was unable to open the macro library referenced by the SASMSTORE = libref 
     MYMACROS. 
ERROR: An error occurred during the execution of the %COPY statement. 

如何更改包含宏的目录的名称，以便可以在各种程序中调用这些宏？是否可以预先命名目录与sasmacr不同？

Answer 1

我不认为你可以将目录从SASMACR重命名，并仍然直接使用它。但是，您可以使用PROC CATALOG来管理SASMACR目录。

你想要做的是，当你想包括一个特定的宏，将它从proc catalog从其源位置复制到您选择的SASMSTORE位置。

喜欢的东西：

libname myMacros 'C:\temp'; 
libname pwd '.'; 

options mstored sasmstore=pwd; 

proc catalog catalog=myMacros.HelloWorld; 
    copy out=pwd.sasmacr; 
run; 
quit; 


%HelloWorld(); 

现在 - 我建议这可能是矫枉过正;真的没有理由以这种方式分开的宏目录。如果您喜欢单独包含文件的想法，您可能需要考虑Autocall宏（您不会将它们存储为已编译，但存储它们的源代码和按需编译）;无论如何，真正编译一个宏在SAS中几乎没有任何成本。但是如果使用存储编译的宏是你喜欢的，那么这种方法可能是最好的方法。

当然，我认为更简单的方法是离开目录SASMACR.SAS7BCAT并使用目录名称来确定它是什么，然后将librefs附加到您的sasmstore选项值。

Answer 2

至少在使用SAS 9.4的Unix上，您可以使用SASAUTOS选项指向使用ZIP引擎的FILEREF，以便将所有宏定义存储在一个ZIP文件中。

一个“诀窍”是，您需要更改ZIP文件中成员文件的名称。通常在Unix上，SASAUTOS要求源文件使用小写的宏名称命名，其.sas扩展名（helloworld.sas）。但是，对于SASAUTOS使用ZIP文件，应该使用大写字母的名称以NO扩展名（HELLOWORLD）命名成员。

filename mymacros zip '~/mymacros.zip'; 
options insert=(sasautos=(mymacros)) ; 

EDIT

不幸的是这种方法会导致SAS生成错误：消息时在ZIP文件中没有找到宏源文件，即使是在SASAUTOS选项另一个文件最终发现搜索路径。

Answer 3

从DATA_NULL_我已收到如何使用具有不同名称的现有目录的答案。使用CATNAME语句。所以如果你有目录TEST.CAT1和TEST.CAT2，你可以使用CATNAME语句来使TEST.SASMACR成为两个宏的连接。

CATNAME test.sasmacr 
    (test.cat1 (ACCESS=READONLY) 
    test.cat2 (ACCESS=READONLY) 
) 
; 

您现在可以将SASMSTORE选项指向TEST libref。

option mstored sasmstore=test; 

这里是你如何可以创建使用PROC CATALOG来复制已经被编译成一个SASMACR目录与名称不同的目录成员这样的单独目录的例子。

libname templib '~/test/cat1'; 
libname permlib '~/test'; 
options mstored sasmstore=templib; 

%macro HelloWorld1()/store source; 
    data _null_; 
    put "Hello, World! &sysmacroname"; 
    run; 
%mend; 

%macro HelloWorld2()/store source; 
    data _null_; 
    put "Hello, World! &sysmacroname"; 
    run; 
%mend; 

proc catalog cat=templib.sasmacr ; 
    copy out=permlib.cat1; 
     select helloworld1 /et=macro; 
    run; 
    copy out=permlib.cat2; 
     select helloworld2 /et=macro; 
    run; 
quit; 

现在使用CATNAME命令将目录链接在一起。

options mstored sasmstore=permlib; 
CATNAME permlib.sasmacr 
    (permlib.cat1 (ACCESS=READONLY) 
    permlib.cat2 (ACCESS=READONLY) 
); 

%helloworld1; 
%helloworld2;