log4perl如何同时写入STDERR和一个文件？

我试着设置了两个附加目的地，但它似乎只写入STDERR：log4perl如何同时写入STDERR和一个文件？

my $header = "######$scriptname $version"; 
use Log::Log4perl qw(:easy); 
Log::Log4perl->easy_init($DEBUG); 
my $logger = get_logger(); 
my $layout = Log::Log4perl::Layout::PatternLayout->new(
"%d %p> %F{1}:%L %M - %m%n"); 
my $appender = Log::Log4perl::Appender->new(
     "Log::Dispatch::File", 
     filename=>$scriptname.".log", 
     mode => "append" 
); 
$appender->layout($layout); 
my $stderr = Log::Log4perl::Appender::Screen->new(
     stderr =>0, 
     ); 

$stderr->layout($layout); 
$logger->info($header);

来源

2011-09-08 shigeta

这不是自定义的appender混合easy_init一个好主意。您可以通过向记录器$logger->add_appender($appender)添加appender来解决此问题。但是这会导致重复的消息，因为您已经在easy_init中设置了appender。

我建议你改用配置。你可以在你的代码中嵌入配置：

use strict; use warnings; 

use Log::Log4perl; 

Log::Log4perl->init(\<<CONFIG); 
log4perl.rootLogger = DEBUG, screen, file 

log4perl.appender.screen = Log::Log4perl::Appender::Screen 
log4perl.appender.screen.stderr = 0 
log4perl.appender.screen.layout = PatternLayout 
log4perl.appender.screen.layout.ConversionPattern = %d %p> %F{1}:%L %M - %m%n 

log4perl.appender.file = Log::Log4perl::Appender::File 
log4perl.appender.file.filename = 1.log 
log4perl.appender.file.mode = append 
log4perl.appender.file.layout = PatternLayout 
log4perl.appender.file.layout.ConversionPattern = %d %p> %F{1}:%L %M - %m%n 
CONFIG 

my $logger = Log::Log4perl->get_logger(); 
$logger->info("my message");

来源

2011-09-08 22:48:21

是的，我可以看到easy_init不适合我在这种情况下。所有这些都很好地工作，除了我不能让你的嵌入式CONFIG工作 - 我使用了一个quotelist并将它放到init中。谢谢！ – shigeta

日志:: Log4Perl文档有答案中途通过“隐形记录器”部分： http://search.cpan.org/~mschilli/Log-Log4perl-1.49/lib/Log/Log4perl.pm#Stealth_loggers

use Log::Log4perl qw(:easy); 

Log::Log4perl->easy_init({ level => $DEBUG, 
          file  => ">>test.log", 
          layout => '%F{1}-%L-%M: %m%n' }, 
          { level => $DEBUG, 
          file  => "STDOUT", 
          layout => '%m%n' }, 
         );

我有同样的问题。 ..甚至5年后，这是张贴，这仍然是在谷歌的头版搜索“perl log4perl写入文件和屏幕”

来源

2017-07-15 00:51:59 Kyle

log4perl如何同时写入STDERR和一个文件？

回答

相关问题