VBA函数调用VBA sub将数组打印到工作表

Question

目前我有一个用户定义的函数，它运行几个涉及矩阵生成的例程。要检查这些矩阵是否已正确生成，我想将它们放在工作表上。用户定义函数工作正常，我已经添加了低于进去的地方，我想找出什么是数组中：

Call CheckArray(TestArray) 

其中“TestArray”在上面取决于我想要的阵列上看看。

的“CheckArray”子程序如下：

Sub CheckArray(MyArray As Variant) 
MatrixRows = UBound(MyArray, 1) 
MatrixCols = UBound(MyArray, 2) 

MsgBox MyArray(11, 2) 
MsgBox "Matrix size = " & MatrixRows & " rows x " & MatrixCols & " columns" 

ActiveWorkbook.Worksheets("Check array").[A1].Resize(MatrixRows, MatrixCols) = MyArray 
End Sub 

注意，我把两个MSGBOX命令在那里检查子被正确调用，它是工作，它是。此外，它还返回了我请求的特定位置的值，并且还说明了我所查看的特定矩阵的大小，所以数据似乎正在被正确读取 - 问题在于随后从新的子文件中写入该数据。

当我包含最后一行时，它不会将我的数组打印到工作表，并且也会停止用户定义的函数正常工作。有谁知道为什么这不起作用？

用户定义的函数是否可以调用打印到工作表的子工具？有没有办法来解决这个问题？

Answer 1

总结：

由于我使用的是进入了一个电池在工作表用户定义的函数，我不能将数据导出到任何地方，但该单元格。但是，我可以在即时窗口中查看数组。

在MS Excel 2010中，可以在VBA编辑器（Alt + F11）中找到立即窗口，然后单击视图 - >立即窗口（Ctrl + G）。

要我的数组导出到即时窗口我应该进入到这一点我的代码要查看后阵：

Call WriteArrayToImmediateWindow(MyArray) 

其中“MYARRAY”是我的数组的名字，不管它是什么。

这将再调用 'WriteArrayToImmediateWindow' 子，其是：

Sub WriteArrayToImmediateWindow(arrSubA As Variant) 

Dim rowString As String 
Dim iSubA As Long 
Dim jSubA As Long 

rowString = "" 

Debug.Print 
Debug.Print "The array is: " 
For iSubA = 1 To UBound(arrSubA, 1) 
    rowString = arrSubA(iSubA, 1) 
    For jSubA = 2 To UBound(arrSubA, 2) 
     rowString = rowString & "," & arrSubA(iSubA, jSubA) 
    Next jSubA 
    Debug.Print rowString 
Next iSubA 

End Sub 

信用为上述进入User3706920：How to print two dimensional array in Immediate window in VBA?

编辑：

我决定观看阵列中立即窗口并不总是有用的，我需要在Excel中查看数据逗号分隔。如果你想要做同样遵循以下说明：

到数组导出到您应该进入阵列后您的代码这是一个文本文件，要查看：

Call WriteToFile(MyArray) 

其中“MYARRAY”又是你想要查看的数组的名称。在“将writeToFile宏如下：

Sub WriteToFile(arrSubA As Variant) 
'To export array to a text file 
    'Setup 
    Dim FSO As Object 
    Dim ofs As Object 
    Dim Output As Variant 
    Dim rowString As String 
    Dim iSubA As Long 
    Dim jSubA As Long 
    rowString = "" 

    'Create file 
    Set FSO = CreateObject("Scripting.FileSystemObject") 
    Dim oFile As Object 
    Set oFile = FSO.CreateTextFile("C:\Users\" & Environ$("username") & "\Desktop\Array.txt") 
    oFile.Close 
    For iSubA = 1 To UBound(arrSubA, 1) 
     rowString = arrSubA(iSubA, 1) 
     For jSubA = 2 To UBound(arrSubA, 2) 
      rowString = rowString & "," & arrSubA(iSubA, jSubA) 
     Next jSubA 
     If Len(Dir("C:\Users\" & Environ$("username") & "\Desktop\Array.txt")) > 0 Then 
      Set ofs = FSO.OpenTextFile("C:\Users\" & Environ$("username") & "\Desktop\Array.txt", 8, True) 
     End If 
     ofs.WriteLine rowString 
     ofs.Close 
    Next iSubA 
End Sub 

要快速查看在Excel输出数组没有任何逗号我建议分配下面宏到按钮：

Sub OpenArrayFile() 
'To open array text file in Excel 
    Workbooks.OpenText Filename:="C:\Users\" & Environ$("username") & "\Desktop\Array.txt", Origin:= _ 
     xlMSDOS, StartRow:=1, DataType:=xlDelimited, TextQualifier:=xlDoubleQuote _ 
     , ConsecutiveDelimiter:=False, Tab:=True, Semicolon:=False, Comma:=True _ 
     , Space:=False, Other:=False, FieldInfo:=Array(1, 1), _ 
     TrailingMinusNumbers:=True 
End Sub 

希望这是有用的人太！