在XSLT中交叉引用数据的首选方法是使用<xsl:key>
。下面的XSLT应该这样做:
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:foi="foifoifoi" xmlns:rdf="rdfrdf"
exclude-result-prefixes="foi rdf">
<xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>
<xsl:key name="kService" match="foi:serviceInfo" use="@rdf:ID"/>
<xsl:template match="/*">
<div>
<xsl:apply-templates select="foi:serviceRequest" />
</div>
</xsl:template>
<xsl:template match="foi:serviceRequest">
<xsl:variable name="referenceId"
select="substring(foi:servicing/@rdf:resource, 2)" />
<xsl:variable name="info" select="key('kService', $referenceId)[1]"/>
<div>
<xsl:value-of select="foi:creationDate"/>
<xsl:apply-templates select="$info/*" />
</div>
</xsl:template>
<xsl:template match="foi:serviceInfo/*">
<xsl:value-of select="concat(' - ', .)"/>
</xsl:template>
</xsl:stylesheet>
(我不得不作出了命名空间foi
和rdf
因为你没有说明他们请正确的URI代替)。当在这个XML运行(具有根节点加入):
<root xmlns:foi="foifoifoi" xmlns:rdf="rdfrdf">
<foi:serviceInfo rdf:ID="SI1">
<foi:serviceName>Sewer</foi:serviceName>
<foi:problemCode>SI1</foi:problemCode>
<foi:division>Water</foi:division>
</foi:serviceInfo>
<foi:serviceInfo rdf:ID="SI2">
<foi:serviceName>Recycling</foi:serviceName>
<foi:problemCode>SI2</foi:problemCode>
<foi:division>Solid Waste</foi:division>
</foi:serviceInfo>
<foi:serviceRequest rdf:ID="R1">
<foi:creationDate>29 03 2013</foi:creationDate>
<foi:servicing rdf:resource="#SI1"/>
</foi:serviceRequest>
<foi:serviceRequest rdf:ID="R2">
<foi:creationDate>29 06 2013</foi:creationDate>
<foi:servicing rdf:resource="#SI2"/>
</foi:serviceRequest>
</root>
这产生:
<div>
<div>29 03 2013 - Sewer - SI1 - Water</div>
<div>29 06 2013 - Recycling - SI2 - Solid Waste</div>
</div>
要点:
- 一个
xsl:key
的使用,以允许通过特定的定位foi:serviceInfo
ID
。
- 使用
key()
函数按ID查找相关foi:serviceInfo
。最后的[1]
限制了第一场比赛。我不确定是否有可能会有不止一场比赛,但在那里?
- 用于将
foi:serviceInfo
的任何子项作为连字符加上元素值的模板。
非常感谢JL。这工作得很好。在这种情况下,可以有多个与serviceInfo关联的serviceRequest。 – user2035965
我看到,所以多个serviceRequest可以引用同一个serviceInfo,但每个serviceRequest只引用一个serviceInfo(换句话说,serviceRequest-> serviceInfo是多个 - >一个)? – JLRishe
是的,这是正确的。再次感谢 – user2035965