ASP.NET防止登录的时候EmailConfirmed是假的使用VB.Net

Question

我想补充的，如果在下面的代码声明否认谁没有证实他们的电子邮件地址的用户 - 像这样的伪代码：

if EmailConfirmed = false Then RedirectToURL and user = "" 

在

Protected Sub LogIn(sender As Object, e As EventArgs) 
    If IsValid Then 

     ' Validate the user password 
     Dim manager = Context.GetOwinContext().GetUserManager(Of ApplicationUserManager)() 
     Dim signinManager = Context.GetOwinContext().GetUserManager(Of ApplicationSignInManager)() 


     ' This doen't count login failures towards account lockout 
     ' To enable password failures to trigger lockout, change to shouldLockout := True 
     Dim result = signinManager.PasswordSignIn(Email.Text, Password.Text, RememberMe.Checked, shouldLockout:=True) 

     Select Case result 
      Case SignInStatus.Success 
       IdentityHelper.RedirectToReturnUrl(Request.QueryString("ReturnUrl"), Response) 
       Exit Select 
      Case SignInStatus.LockedOut 
       Response.Redirect("/Account/Lockout") 
       Exit Select 
      Case SignInStatus.RequiresVerification 
       Response.Redirect(String.Format("/Account/TwoFactorAuthenticationSignIn?ReturnUrl={0}&RememberMe={1}", 
              Request.QueryString("ReturnUrl"), 
              RememberMe.Checked), 
           True) 
       Exit Select 
      Case Else 
       FailureText.Text = "Invalid login attempt" 
       ErrorMessage.Visible = True 
       Exit Select 
     End Select 

    End If 
End Sub 

    End Class 

我已经看到了它在C＃中做，但我无法复制或准确地转换。感谢您的任何帮助。

UPDATE

当我使用的代码有@HumbleBeginnings链接，并转换到VB我得到：

Dim user = Await.UserManager.FindByNameAsync(model.Email) 
If user IsNot Nothing Then If Not 
Await UserManager.IsEmailConfirmedAsync(user.Id) Then 
ViewBag.errorMessage = "You must have a confirmed email to log on." 
Return  
View("Error") 
End If 

不过是说，等待着只能异步方法一起使用，可以考虑改变这个方法与异步改性剂和改变它的返回类型任务

Answer 1

这就是我如何结束解决这一问题：

Protected Async Sub LogIn(sender As Object, e As EventArgs) 
    If IsValid Then 

     ' Validate the user password 
     Dim manager = Context.GetOwinContext().GetUserManager(Of ApplicationUserManager)() 
     Dim signinManager = Context.GetOwinContext().GetUserManager(Of ApplicationSignInManager)() 

     ' This doen't count login failures towards account lockout 
     ' To enable password failures to trigger lockout, change to shouldLockout := True 
     Dim result = signinManager.PasswordSignIn(Email.Text, Password.Text, RememberMe.Checked, shouldLockout:=True) 

     Dim user = Await manager.FindByNameAsync(Email.Text) 
     If user Is Nothing Then 
      ModelState.AddModelError("", "Invalid login attempt.") 
     Else 
     End If 
     'Add this to check if the email was confirmed. 
     If Not Await manager.IsEmailConfirmedAsync(user.Id) Then 
      ConfirmationExpected.Text = "Your email address has not been confirmed <br/> <br/>Please Check your email (including spam folder) <br/>OR Click 'Register' to have a new confirmation email generated." 
      ConfirmationRequired.Visible = True 

     Else 

      Select Case result 
       Case SignInStatus.Success 
        IdentityHelper.RedirectToReturnUrl(Request.QueryString("ReturnUrl"), Response) 
        Exit Select 
       Case SignInStatus.LockedOut 
        Response.Redirect("/Account/Lockout") 
        Exit Select 
       Case SignInStatus.RequiresVerification 
        Response.Redirect(String.Format("/Account/TwoFactorAuthenticationSignIn?ReturnUrl={0}&RememberMe={1}", 
                Request.QueryString("ReturnUrl"), 
                RememberMe.Checked), 
             True) 
        Exit Select 
       Case Else 
        FailureText.Text = "Invalid login attempt" 
        ErrorMessage.Visible = True 
        Exit Select 
      End Select 

     End If 

    End If 
End Sub 

这是添加的代码：

Dim user = Await manager.FindByNameAsync(Email.Text) 
    If user Is Nothing Then 
     ModelState.AddModelError("", "Invalid login attempt.") 
    Else 
    End If 
    'Add this to check if the email was confirmed. 
    If Not Await manager.IsEmailConfirmedAsync(user.Id) Then 
     ConfirmationExpected.Text = "Your email address has not been confirmed <br/> <br/>Please Check your email (including spam folder) <br/>OR Click 'Register' to have a new confirmation email generated." 
     ConfirmationRequired.Visible = True 

    Else 

Answer 2

退房THIS链接，头下特别是部分“需要登录后才电子邮件确认”。帐户/注册控制器中有一条注释，似乎有窍门。它在C＃中，但它应该让你接近。希望这可以帮助。

Answer 3

我发现，要检查是否在尝试的电子邮件确认登录。否则，他们将在登录到其他页面时登录。这是我做出的一个变化，显示了逻辑顺序。我重定向到未经验证的页面，以防止反XSRF问题。

Protected Async Sub LogIn(sender As Object, e As EventArgs) 
    If IsValid Then 
     Dim manager = Context.GetOwinContext().GetUserManager(Of ApplicationUserManager)() 
     Dim signinManager = Context.GetOwinContext().GetUserManager(Of ApplicationSignInManager)() 

     Dim user = Await manager.FindByNameAsync(Email.Text) 
     If user Is Nothing Then 
      ModelState.AddModelError("", "Invalid login attempt.") 
      FailureText.Text = "Invalid login attempt" 
      ErrorMessage.Visible = True 
     Else 
      'Add this to check if the email was confirmed. I check this before even attempting a login- as it logs the user in, regardless, if I do not. 
      If Not Await manager.IsEmailConfirmedAsync(user.Id) Then 
       Response.Redirect("/Account/NotValidated") 
      Else 
       Dim result = signinManager.PasswordSignIn(Email.Text, Password.Text, RememberMe.Checked, shouldLockout:=True) 

       Select Case result 
        Case SignInStatus.Success 
         IdentityHelper.RedirectToReturnUrl(Request.QueryString("ReturnUrl"), Response) 

        Case SignInStatus.LockedOut 
         Response.Redirect("/Account/Lockout") 

        Case SignInStatus.RequiresVerification 
         Response.Redirect(String.Format("/Account/TwoFactorAuthenticationSignIn?ReturnUrl={0}&RememberMe={1}", 
                 Request.QueryString("ReturnUrl"), 
                 RememberMe.Checked), 
              True) 

        Case Else 
         FailureText.Text = "Invalid login attempt" 
         ErrorMessage.Visible = True 

       End Select 
      End If 
     End If 

    End If 

Answer 4

，以验证电子邮件已被证实可以通过将下面的代码在你的洛

If IsValid Then 
     ' Validate the user password 
     Dim manager = Context.GetOwinContext().GetUserManager(Of ApplicationUserManager)() 
     Dim signinManager = Context.GetOwinContext().GetUserManager(Of ApplicationSignInManager)() 

     ' este segmento valida que el usuario ya confirmo su cuenta de correo electronico, 
     ' de lo contrario no intenta ingresar 
     ' you need add onli this code block -- init validate EmailConfirmed is false using VB.Net 
     Dim user As ApplicationUser = manager.FindByName(Email.Text) 
     If user Is Nothing OrElse Not manager.IsEmailConfirmed(user.Id) Then 
      FailureText.Text = "El usuario no existe o bien no ha sido confirmado. <br/> Por favor confirmar su correo electrónico (Verifique la carpeta spam o correo no deseado). <br/> O Haga clic en 'Registrarse como nuevo usuario'" 
      ErrorMessage.Visible = True 
      Email.Focus() 
      Return 
     End If 
     ' end validate EmailConfirmed is false using VB.Net 

     ' This doen't count login failures towards account lockout 
     ' To enable password failures to trigger lockout, change to shouldLockout := True 
     Dim result = signinManager.PasswordSignIn(Email.Text, Password.Text, RememberMe.Checked, shouldLockout:=True) 
     Select Case result 
      Case SignInStatus.Success 
       logger.Info(Email.Text & "│ usuario INICIO sesion ") ' comentario para la bitacora de logg 
       System.Web.Security.FormsAuthentication.RedirectFromLoginPage(Email.Text, True) 
       'IdentityHelper.RedirectToReturnUrl(Request.QueryString("ReturnUrl"), Response) 
       Exit Select 
      Case SignInStatus.LockedOut 
       Response.Redirect("~/Account/Lockout") 
       Exit Select 
      Case SignInStatus.RequiresVerification 
       Response.Redirect(String.Format("~/Account/TwoFactorAuthenticationSignIn?ReturnUrl={0}&RememberMe={1}", 
               Request.QueryString("ReturnUrl"), 
               RememberMe.Checked), 
            True) 
       Exit Select 
      Case Else 
       FailureText.Text = "Intento de inicio de sesión inválido " 
       ErrorMessage.Visible = True 
       Email.Focus() 
       Exit Select 
     End Select 
    End If 
End Sub