重构生成文件的elisp代码

Question

我编写了一个简单的emacs模块，它生成我用于博客的静态站点生成器的标准模板。

(defun hakyll-site-location() 
    "Return the location of the Hakyll files." 
    "~/Sites/hblog/") 

(defun hakyll-new-post (title tags) 
    "Create a new Hakyll post for today with TITLE and TAGS." 
    (interactive "sTitle: \nsTags: ") 
    (let ((file-name (hakyll-post-title title))) 
    (set-buffer (get-buffer-create file-name)) 
    (markdown-mode) 
    (insert 
    (format "---\ntitle: %s\ntags: %s\ndescription: \n---\n\n" title tags)) 
    (write-file 
    (expand-file-name file-name (concat (hakyll-site-location) "posts"))) 
    (switch-to-buffer file-name))) 

(defun hakyll-new-note (title) 
    "Create a new Note with TITLE." 
    (interactive "sTitle: ") 
    (let ((file-name (hakyll-note-title title))) 
    (set-buffer (get-buffer-create file-name)) 
    (markdown-mode) 
    (insert (format "---\ntitle: %s\ndescription: \n---\n\n" title)) 
    (write-file 
    (expand-file-name file-name (concat (hakyll-site-location) "notes"))) 
    (switch-to-buffer file-name))) 

(defun hakyll-post-title (title) 
    "Return a file name based on TITLE for the post." 
    (concat 
    (format-time-string "%Y-%m-%d") 
    "-" 
    (replace-regexp-in-string " " "-" (downcase title)) 
    ".markdown")) 

(defun hakyll-note-title (title) 
    "Return a file name based on TITLE for the note." 
    (concat 
    (replace-regexp-in-string " " "-" (downcase title)) 
    ".markdown")) 

现在，这种方法可行，但它可以干一点点，但我自己并不知道有足够的elisp来做。

• hakyll-new-post和hakyll-new-note非常相似，可以用干燥起来做，但我不知道如何正确的参数传递给任何重构功能
• 我硬编码hakyll-site-location。有什么方法可以请求并将配置存储在我的emacs dotfiles中？

欢迎任何帮助或指向文档的指针。

Answer 1

下面是代码。我不能保证它能正常工作，但如果它在以前工作，那么它现在应该可以工作了。

(defvar hakyll-site-location "~/Sites/hblog/" 
    "Return the location of the Hakyll files.") 

(defun hakyll-new-post (title tags) 
    "Create a new Hakyll post for today with TITLE and TAGS." 
    (interactive "sTitle: \nsTags: ") 
    (hakyll-do-write 
    (format "%s/posts/%s-%s.markdown" 
      hakyll-site-location 
      (format-time-string "%Y-%m-%d") 
      (replace-regexp-in-string " " "-" (downcase title))) 
    (format "---\ntitle: %s\ntags: %s\ndescription: \n---\n\n" 
      title 
      tags))) 

(defun hakyll-new-note (title) 
    "Create a new Note with TITLE." 
    (interactive "sTitle: ") 
    (hakyll-do-write 
    (format "%s/notes/%s.markdown" 
      hakyll-site-location 
      (replace-regexp-in-string " " "-" (downcase title))) 
    (format "---\ntitle: %s\ndescription: \n---\n\n" title))) 

(defun hakyll-do-write (file-name str) 
    (find-file file-name) 
    (insert str) 
    (save-buffer)) 

您可以在点文件中使用(setq hakyll-site-location "~/Sites/")来设置位置。 您甚至可以将defvar更改为defcustom并使用自定义来设置位置。