tsql动态sql最佳方法

Question

我有下面的工作，但想知道如果我下面有什么可以优化或如果有更好的方式做dynamive查询。

我有一个网页表单，用户输入一个位置和收集日期。对于收集的日期，我收集了收集日期和收集日期。用户将收件日期保留为空，在这种情况下，它将执行比收集起始日期更长的任何操作。

请注意我如何在下面的IS NOT NULL和1 = 1。还想知道如果动态SQL是最好的方法，或者是否有一个更简单的方法来做到这一点。

DECLARE @sql varchar(max); 

    SET @sql = 'SELECT * from tblProgram WHERE 1=1' 

    IF (@Location IS NOT NULL) 
    BEGIN 
     SET @sql = @sql + ' AND Location = ' + @Location 
    END  

    IF (@FromDateCollected IS NOT NULL AND @ToDateCollected IS NOT NULL) 
    BEGIN 
     SET @sql = @sql + ' AND pw.DateCollected >= ' + QUOTENAME(convert(varchar, @FromDateCollected,101),'''') 
     + ' AND pw.DateCollected <= ' + QUOTENAME(convert(varchar, @ToDateCollected,101),'''') 

    END 
    ELSE IF (@FromDateCollected IS NOT NULL AND @ToDateCollected IS NULL) 
    BEGIN 
     SET @sql = @sql + ' AND pw.DateCollected >= ' + QUOTENAME(convert(varchar, @FromDateCollected,101),'''') 

    END 

    exec(@sql) 

Answer 1

那么你可以做ta.speot.is评论使用静态SQL并做

WHERE x is null or x > date_column? 

但是如果你坚持使用动态SQL，你应该使用使用sp_executeSQL

参数化的SQL语句

它更易于阅读，您不必使用quotename，而且您可以免受SQL注入攻击

DECLARE @Location int 
DECLARE @FromDateCollected datetime 
DECLARE @ToDateCollected datetime 
SET @ToDateCollected = '1/02/2012' 



DECLARE @sql nvarchar(max) 
DECLARE @ParmDefinition nvarchar(max) 

SET @ParmDefinition = N'@Location int , @FromDateCollected datetime, @ToDateCollected datetime '; 

SET @sql = N'SELECT * from tblProgram WHERE 1=1' 

IF (@Location IS NOT NULL) 
BEGIN 
    SET @sql = @sql + N' AND Location = @Location' 
END  

IF (@FromDateCollected IS NOT NULL AND @ToDateCollected IS NOT NULL) 
BEGIN 
    SET @sql = @sql + N' AND pw.DateCollected >= @FromDateCollected ' 
     + N' AND pw.DateCollected <= @ToDateCollected ' 

END 
ELSE IF (@FromDateCollected IS NOT NULL AND @ToDateCollected IS NULL) 
BEGIN 
    SET @sql = @sql + N' AND pw.DateCollected >= @FromDateCollected' 

END 

exec sp_executesql @SQL, @ParmDefinition, @Location = @Location, 
            @FromDateCollected = @FromDateCollected, 
             @ToDateCollected = @ToDateCollected 

DEMO