从Excel中填充Word文档而不删除书签

Question

我想根据Excel中的数据填充Word文档。由于特定工作要求的数量众多，我需要在Word中保留书签。我已经将这些网站用作资源。

Replace Text in Bookmark in Word without Deleting Bookmark http://wordmvp.com/FAQs/MacrosVBA/InsertingTextAtBookmark.htm http://www.wiseowl.co.uk/blog/s199/word-bookmarks.htm

我在CopyCell的最后一行得到一个编译错误。

Option Explicit 
Dim wd As New Word.Application 
Dim DataCell As Range 

Sub ReportData() 

'Open word template 
wd.Documents.Open (Range("D4") & Range("D5")) 
wd.Visible = True 

'Creates range with all of the data used in the report 
Dim DataRange As Range 
Range("D7").Select 
Set DataRange = Range(ActiveCell, ActiveCell.End(xlDown)) 

'Uses copycell function. "Name" is the bookmark name, 0 is the Rowoffset 
For Each DataCell In DataRange 
    CopyCell "Name", 0 
    CopyCell "Employer", 1 
Next 

End Sub 

Sub CopyCell(BookMarkName As String, RowOffset As Integer) 

Dim BMRange As Word.Range 

wd.Selection.GoTo What:=wdGoToBookmark, Name:=BookMarkName 
Set BMRange = wd.Selection.Range.Duplicate 
BMRange.Text = DataCell.Offset(RowOffset, 0).Value 
wd.Bookmarks.Add BookMarkName, BMRange 

End Sub 

Answer 1

Bookmarks是不是一个Document对象的属性字Application对象

，所以你必须改变：

wd.Bookmarks.Add BookMarkName，BMRange

到：

wd.ActiveDocument.Bookmarks.Add BookMarkName，BMRange

此外，您可以考虑一下如下：

• 你应该限制使用公共变量来这里确实不可避免的（如：与用户窗体通信）

• 避免Activate/ActiveXXX/Selection/Select模式并使用完全限定范围参考

• 您正在遍历“垂直”范围，然后您将当前单元格“垂直”偏移， （即一个单元向下）：可能是你想要“水平”偏移（即到相邻单元）？

上述所有我会建议你的代码的重构如下内容：

Option Explicit 

Sub ReportData() 

    Dim wd As Word.Application 
    Dim DataCell As Range 

    Set wd = New Word.Application 

    'Open word template 
    wd.Documents.Open Range("D4") & Range("D5") 
    wd.Visible = True 

    'Creates range with all of the data used in the report 
    With Range("D7") 
     'Uses copycell function. "Name" is the bookmark name, 0 is the Rowoffset 
     For Each DataCell In Range(.Cells, .End(xlDown)) 
      CopyCell wd, DataCell, "Name", 0 
      CopyCell wd, DataCell, "Employer", 1 
     Next 
    End With 

    wd.ActiveDocument.Close True '<--| close and save word document 
    wd.Quit '<--| close word application 
    Set wd = Nothing '<--| clean memory 
End Sub 

Sub CopyCell(wd As Word.Application, DataCell As Range, BookMarkName As String, ColOffset As Integer) 

    Dim BMRange As Word.Range 

    wd.Selection.GoTo What:=wdGoToBookmark, Name:=BookMarkName 
    Set BMRange = wd.Selection.Range.Duplicate 
    BMRange.Text = DataCell.Offset(0, ColOffset).Value 
    wd.ActiveDocument.Bookmarks.Add BookMarkName, BMRange 

End Sub