减去值

Question

我输入文件如下

100A 2000 
100B 150 
100C 800 
100A 1000 
100B 100 
100C 300 

我想减去第2列值在列中的每个uniq的值1 所以出来放应该像

100A 1000 
100B 50 
100C 500 

我已经试过

awk '{if(!a[$1])a[$1]=$2; else a[$1]=$2-a[$1]}END{ for(i in a)print i" " a[i]}' file 

但放出来是：

100A 0 
100B 0 
100C 0 

请指教

Answer 1

这么多的（轻微）的变化同一主题。

awk ' 
    !($1 in a) {a[$1]=$2; next} 
    {a[$1]-=$2} 
    END {for (i in a) printf "%s %d\n",i,a[i]} 
' input.txt 

如果您愿意，可将其叠加为一行。

请记住，awk结构由多个condition { statement }对组成，因此您可以比使用if..else更优雅地表达您的需求。 （并不是说这里就是这种情况 - 这是一个足够简单的awk脚本，它可能并不重要，除非你是一个纯粹主义者。]）

另外，要小心测试值的方式，已经在你的if的条件下完成了这个问题。请注意，a[$1]都测试该数组索引处的值是否为非零值和如果先前不存在，则会使索引存在空值。如果您想检查索引是否存在，请使用$1 in a。

---

更新基于对您的问题评论...

如果你想减去从第一项最后，忽略之间的，那么你需要保持记录你的第一个和你的最后一个。像这样的东西可能就足够了。

awk ' 
    !($1 in a){a[$1]=$2;next} 
    {b[$1]=$2} 
    END {for(i in b)if(i in a)print i,a[i]-b[i]} 
' input.txt 

请注意，正如埃德提到的，这会产生随机顺序的输出。如果你想要输出的顺序，你需要一个额外的数组来跟踪订单。例如，这将使用顺序的项目，首先看出：

awk ' 
    !($1 in a) { 
    a[$1]=$2; 
    o[++n]=$1; 
    next 
    } 
    { 
    b[$1]=$2 
    } 
    END { 
    for (n=1;n<=length(o);n++) 
     print o[n],a[o[n]]-b[o[n]] 
    } 
' i 

注意，所使用的length()函数来确定数组中元素的数目是不普遍之中AWK的方言，但它确实在两个工作gawk和one-true-awk（用于FreeBSD等）。

Answer 2

这AWK的一行这项工作：

awk '{if($1 in a)a[$1]=a[$1]-$2;else a[$1]=$2} 
     END{for(x in a) print x, a[x]}' file 

Answer 3

您可以使用此awk：

awk 'a[$1]{a[$1]=a[$1]-$2; next} {a[$1]=$2} END{for(v in a){print v, a[v]}}' file 

Answer 4

在awk中。使用条件运算符值配售/减法，以保持紧：

$ awk '{ a[$1]+=($1 in a?-$2:$2) } END{ for(i in a)print i, a[i] }' file 
100A 1000 
100B 50 
100C 500 

解释：

{ 
    a[$1]+=($1 in a?-$2:$2) # if $1 in a already, subtract from it 
           # otherwise add value to it 
} 
END { 
    for(i in a)    # go thru all a 
     print i, a[i]   # and print keys and values 
} 

Answer 5

给你提供的样品输入，所有你需要的是：

$ awk '$1 in a{print $1, a[$1]-$2} {a[$1]=$2}' file 
100A 1000 
100B 50 
100C 500 

如果是这样的不是所有你需要的，然后提供更真实的代表性样本输入/输出，包括那些不够好的情况。