有效的方式来更新的XMLListCollection

Question

我有以下代码：

private var xmlC:XMLListCollection = new XMLListCollection(); 
private var httpS:HTTPService = new HTTPService(); 
private var timer:Timer = new Timer(1000); 
private var xmlData:XML; 
private var xmlDataList:XMLList; 

protected function application1_creationCompleteHandler(event:FlexEvent):void 
{ 
    httpS.url = "data.xml"; 
    httpS.addEventListener(ResultEvent.RESULT, resultHTTP); 
    httpS.resultFormat="e4x"; 
    httpS.send(); 

    timer.start(); 
    timer.addEventListener(TimerEvent.TIMER, updateXMLC); 
} 

private function updateXMLC(event:TimerEvent):void 
{ 
    xmlC.source = xmlDataList; 
    httpS.send(); 
} 

private function resultHTTP(event:ResultEvent):void 
{ 
    xmlData = event.result as XML; 
    xmlDataList = xmlData.dg.rows.row; 
} 

“data.xml中”有5000行，所以我需要在必要时清理它的踪迹。我有，我发现多亏了分析

1. 每次httpS.send（）被调用的方法updateXMLC两个问题，它调用的URLLoader内部这使是不需要再徘徊在内存中的XML，而不被当作垃圾收集
2. 有更新XMLC，每当的XMLListCollection更新更有效的方式，似乎的XMLListCollection的前值不会被垃圾回收

Answer 1

看来这是Flex框架的错误：

• http://bugs.adobe.com/jira/browse/SDK-31920
• http://bugs.adobe.com/jira/browse/SDK-15113
• http://bugs.adobe.com/jira/browse/FP-599
• http://bugs.adobe.com/jira/browse/SDK-11244
• http://bugs.adobe.com/jira/browse/SDK-11982

Answer 2

如果我正确您正在恢复理解你的代码你来自SWF文件所在文件夹中的XML数据。如果是这种情况，那么最可能发生的情况是XML文件正在缓存在浏览器中，并且一次又一次地返回相同的缓存版本。

处理这些问题时，您可以添加一个虚拟URL变量，使浏览器认为您正在检索的文件是新的，并强制它再次恢复该文件。

你可以做这样的事情做到这一点：

httpS.url = "data.xml?random="+Math.floor(Math.random()*1000);

如果不能解决这个问题，那么也许它可以关联到不进行重置持有实际的XML数据的变量。您可以通过您的变量的新实例重置做到这一点：

xmlData = new XML(); 
xmlDataList = new XMLList(); 
xmlC = new XMLListCollection(); 

或者，如果你想要的是简单的复位，你可以尝试使用“刷新（）”包含在Flex中所有列出方法的XMLListCollection 。

重要注意事项：如果您使用任何这些变量进行数据绑定，这可能会导致Flex无法收集数据，因为它正在某处使用。

Answer 3

请求，接收和处理XML需要多长时间？这听起来像是一个相当大的文件，所以如果超过一秒钟，您将同时发生多个对HTTPService的调用（据我所知，您当前的计时器将尝试每秒触发一次请求，无论是否最后一个已经返回）。

我不确定这是你想要的，但我怀疑它。如果我是对的，并且只有在收到来自最后一个响应的请求后才发送请求，那么您最好是摆脱计时器及其函数，然后将resultHTTP方法更改为类似的方法这样的：

private function resultHTTP(event:ResultEvent):void 
{ 
    xmlData = event.result as XML; 
    xmlC.source = xmlData.dg.rows.row; 
    httpS.send(); 
} 

当然，你可以把它放到一个延迟它每次开机：

 
    protected function application1_creationCompleteHandler(event:FlexEvent):void 
    { 
     httpS.url = "data.xml"; 
     httpS.addEventListener(ResultEvent.RESULT, resultHTTP); 
     httpS.resultFormat="e4x"; 

     timer.start(); 
     timer.addEventListener(TimerEvent.TIMER, updateXMLC); 
    } 

    private function updateXMLC(event:TimerEvent):void 
    { 
     timer.stop(); 
     httpS.send(); 
    } 

    private function resultHTTP(event:ResultEvent):void 
    { 
     xmlData = event.result as XML; 
     xmlC.source = xmlData.dg.rows.row; 
     timer.start(); 
    } 

很抱歉，如果我误解了，虽然这个问题...

无论是方式，你可能想要把某种错误的HTTP函数n，因此它也会重新启动定时器（或者做任何你需要做的事）来处理HTTP错误。

Answer 4

我看了代码后会怀疑存在任何内存泄漏，因此我对自己的代码进行了测试。

您发布的代码实际上无法运行。我只是说的最少要跑它像应用标签和import语句（和反标签看到一个http服务周期完成时）：

<?xml version="1.0" encoding="utf-8"?> 
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" creationComplete="application1_creationCompleteHandler(event)"> 
<mx:Script> 
    <![CDATA[ 
     import mx.rpc.http.HTTPService; 
     import mx.collections.XMLListCollection; 
     import mx.rpc.events.ResultEvent; 
     import mx.events.FlexEvent; 

     private var xmlC:XMLListCollection = new XMLListCollection(); 
     private var httpS:HTTPService = new HTTPService(); 
     private var timer:Timer = new Timer(1000); 
     private var xmlData:XML; 
     private var xmlDataList:XMLList; 

     protected function application1_creationCompleteHandler(event:FlexEvent):void 
     { 
      httpS.url = "data.xml"; 
      httpS.addEventListener(ResultEvent.RESULT, resultHTTP); 
      httpS.resultFormat="e4x"; 
      httpS.send(); 

      timer.start(); 
      timer.addEventListener(TimerEvent.TIMER, updateXMLC); 
     } 

     private function updateXMLC(event:TimerEvent):void 
     { 
      xmlC.source = xmlDataList; 
      httpS.send(); 
     } 

     private function resultHTTP(event:ResultEvent):void 
     { 
      counter.text = Number(parseInt(counter.text,10)+1).toString(); 
      xmlData = event.result as XML; 
      xmlDataList = xmlData.dg.rows.row; 
     } 
    ]]> 
</mx:Script> 
<mx:Label id="counter" text="0" horizontalCenter="0" verticalCenter="0" fontSize="72"/> 
</mx:Application> 

好消息是不会有任何内存泄漏你的代码。 Profiler中也没有任何游荡物体。

坏消息是你在你的应用程序中做了什么（代码不在这里发布，因为什么原因省略） - 这是你有泄漏/游荡物体的地方。

您可以在附加代码的分析器中看到自己，http服务的前几个周期后内存不会增加。即它不会持续地抓住更多的记忆。 （顺便说一句，我拉入的XML文件大约有8000行，超过1MB）。

如果你想发布更多的代码，高兴看得更远 - 但认为这现在解决了这个谜。 ;）

这里是为了什么你做一些修正：

<?xml version="1.0" encoding="utf-8"?> 
<mx:Application xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" creationComplete="application1_creationCompleteHandler(event)"> 
<mx:Script> 
    <![CDATA[ 
     import mx.rpc.http.HTTPService; 
     import mx.collections.XMLListCollection; 
     import mx.rpc.events.ResultEvent; 
     import mx.events.FlexEvent; 

     [Bindable] private var xmlC:XMLListCollection = new XMLListCollection(); 
     private var httpS:HTTPService = new HTTPService(); 
     private var timer:Timer = new Timer(1000); 
     private var xmlData:XML; 
     private var xmlDataList:XMLList; 
     private var serviceRunning : Boolean = false; 
     private var currentData : String = ''; 

     protected function application1_creationCompleteHandler(event:FlexEvent):void 
     { 
      httpS.url = "data.xml"; 
      httpS.addEventListener(ResultEvent.RESULT, resultHTTP); 
      httpS.resultFormat="e4x"; 
      httpS.send(); 

      timer.start(); 
      timer.addEventListener(TimerEvent.TIMER, updateXMLC); 
     } 

     private function updateXMLC(event:TimerEvent):void 
     { 
      xmlC.source = xmlDataList; 
      if(!serviceRunning){ // don't call for more data until 
       httpS.send();  // you've gotten back last call 
      } 
     } 

     private function resultHTTP(event:ResultEvent):void 
     { 
      // make sure we have differences before rebinding 
      var newData : String = event.result as String; 
      serviceRunning = false; 
      counter.text = Number(parseInt(counter.text,10)+1).toString(); 
      if(newData != currentData){ 
       xmlData = event.result as XML; 
       currentData = newData; 
       xmlDataList = xmlData.dg.rows.row; 
      } 
     } 
    ]]> 
</mx:Script> 
<mx:Label id="counter" text="0" horizontalCenter="0" verticalCenter="0" fontSize="72"/> 
</mx:Application>